如何在Outlook中為答復和轉發設置不同的簽名？

通常，您可以在Outlook中為不同的帳戶設置不同的簽名，但是，曾經嘗試對答復和轉發應用不同的簽名。這意味著，當您回復電子郵件時，將插入signature1；當您轉發電子郵件時，將應用signature2。您如何在Outlook中解決此任務？

設置不同的簽名以使用VBA代碼進行答復和轉發

設置不同的簽名以使用VBA代碼進行答復和轉發

以下VBA代碼可以幫助您為回復和轉發設置不同的簽名，請按以下步驟進行操作：

1。按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 窗口。

2。然後，點擊插入 > 模塊，將以下代碼複製並粘貼到打開的空白模塊中，請參見屏幕截圖：

VBA代碼：為回復和轉發設置不同的簽名:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

備註：在上面的代碼中， 簽名1 和 簽名2 是您要用於回復和轉發的兩個簽名名稱。請根據需要更改名稱。

doc sig forwar回复1