Excel CHOOSE 功能

產品描述

語法和參數

用法與範例

• 例1-基本用法：使用 CHOOSE 僅從列表參數中選擇值的函數
• 例2 –根據多個條件返回不同的結果
• 示例3 –根據條件返回不同的計算結果
• 示例4 –從列表中隨機選擇
• 示例5 –合併 CHOOSE 和 VLOOKUP 函數返回左列中的值
• 示例6 –根據給定日期返回工作日或月份
• 例7 –根據今天返回到下一個工作日/週末

---

產品描述

CHOOSE 函數根據給定的索引號從值參數列表中返回一個值。 例如， CHOOSE(3,”Apple”,”Peach”,”Orange”) 返回Orange，索引號為3，Orange是函數中索引號之後的第三個值。

語法和參數

公式語法

CHOOSE(index_num, value1, [value2], …)

參數

Index_num: 需要。 一個介於1-254到間接之間的數值，該數值將被選擇。 如果index_num超出1-254之間的範圍， CHOOSE 返回 #VALUE! 錯誤值。 如果index_num是十進制值，則將在使用公式之前將其四捨五入為整數。 Value1: 需要。 公式中可以選擇的第一個值。 Value2: 可選的。 第二個，最多254th個值可供選擇。

Value1, value2…可以是數字，文本，公式，單元格引用或定義的名稱。

回報值

CHOOSE 函數根據給定位置從列表中返回一個值。

用法與範例

在這一部分中，我列出了一些簡單但有代表性的示例，以解釋 CHOOSE 的功能。

例1-基本用法：使用 CHOOSE 僅從列表參數中選擇值的函數

公式1：

=CHOOSE(3,"a","b","c","d")

返回值：c，它是index_num 3之後的第三個參數。 CHOOSE 的功能。

注意：如果值是文本，請在值周圍使用雙引號。

公式2：

=CHOOSE(2,A1,A2,A3,A4)

返回值：Kate，A2的值。 由於index_num為2，並且A2是 CHOOSE 的功能。

公式3：

=CHOOSE(4,8,9,7,6)

返回值：6，函數中的第4個list參數。

---

例2 –根據多個條件返回不同的結果

假設您有每個產品的偏差列表，這些偏差需要根據條件進行標記，如下圖所示。

通常，您可以使用IF函數來處理，但在這裡我將介紹如何使用 CHOOSE 輕鬆解決此問題的功能

公式：

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

說明：

(B7>0)+(B7>1)+(B7>5): index_num，B7為2，它大於0和1但小於5，所以我們得到中間結果：

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

眾所周知，True = 1，False = 0，因此公式可以看成：

=CHOOSE(1+1+0,"Top","Middle","Bottom")

然後

=CHOOSE(2,"Top","Middle","Bottom")

結果：中

---

示例3 –根據條件返回不同的計算結果

假設您需要根據數量和價格計算每種產品的返利，如下圖所示：

公式：

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

說明：

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number，B8為102，大於100但小於201，因此在此部分中，其返回結果顯示為：

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

然後

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: 選擇的值，折扣等於價格*金額*折扣百分比，因為這裡index_num為2，所以選擇B8 * C8 * 0.2

返回值：102 * 2 * 0.2 = 40.8

---

示例4 –從列表中隨機選擇

在Excel中，有時您可能需要從給定列表中隨機選擇一個值， CHOOSE 功能可以解決這項工作。

從列表中隨機選擇一個值：

公式：

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

說明：

RANDBETWEEN(1,5): index_num，隨機獲取1到5之間的數字

$D$2,$D$3,$D$4,$D$5,$D$6: 可供選擇的值列表

---

示例5 –合併 CHOOSE 和 VLOOKUP 函數返回左列中的值

通常，我們使用VLOOKUP函數 =VLOOKUP (value, table, col_index, [range_lookup]) 根據表格範圍中的給定值返回一個值。 但是隨著 VLOOKUP 函數，當返回列位於查找列的左側時，它將返回一個錯誤值，如下圖所示：

在這種情況下，您可以將 CHOOSE 函數與VLOOKUP函數一起解決該問題。

公式：

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

說明：

CHOOSE({1,2},B1:B7,A1:A7): 作為VLOOKUP函數中的table_range參數。 {1,2}表示根據VLOOKUP函數中的col_num參數顯示1或2作為index_num參數。 在這裡，VLOOKUP函數中的col_num為2，因此 CHOOSE 功能顯示為 CHOOSE(2, B1:B7,A1:A7)，表示從A1：A7中選擇值。

---

示例6 –根據給定日期返回工作日或月份

隨著 CHOOSE 函數，您還可以根據給定的日期返回相對的工作日和月份。

配方1： 按日期返回工作日

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

說明：

WEEKDAY(): index_num參數，以獲取給定日期的星期幾，例如，WEEKDAY（A5）返回6，則index_num參數為6。

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": 值列表參數，請以“ Sunday”開頭，因為工作日數字“ 1”表示“ Sunday”。

配方2： 按日期返回月份

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

說明：

MONTH(): index_num參數，該參數獲取給定日期的月份數，例如MONTH（A5）返回3。

---

例7 –根據今天返回到下一個工作日/週末

在日常工作中，您可能希望根據今天來計算下一個工作日或週末。 在這裡 CHOOSE 功能也可以幫您一個忙。

例如，今天是12/20/2018，星期四，現在您需要獲取下一個工作日和周末。

配方1： 獲取今天的日期

=TODAY()

結果：12/20/2018

配方2： 獲取今天的工作日數

=WEEKDAY(TODAY())

結果：5（今天是12/20/2018）

工作日號碼列表如下截圖所示：

配方3： 得到下一個工作日

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

說明：

Today(): 返回當前日期

WEEKDAY(TODAY()): 中的index_num參數 CHOOSE 函數，獲取今天的工作日數，例如，星期日為1，星期一為2…

1,1,1,1,1,3,2: 中的值列表參數 CHOOSE 功能。 例如，如果weekday（today（））返回1（Sunday），則從值列表中選擇1，然後整個公式將更改為= Today（）+ 1，這意味著要增加1天以返回下週一。 如果weekday（today（））返回6（Friday），則從值列表中選擇3，因為Friday離下週一3天。

結果（今天是12/20/2018）：

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

配方4： 得到下一個週末

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

說明：

6,5,4,3,2,1,1: 中的值列表參數 CHOOSE 功能。 例如，如果weekday（today（））返回1（Sunday），則從值列表中選擇6，則整個公式將更改為= Today（）+ 6，這意味著要添加6天並在下週六返回。

結果：

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

示例文件