跳到主要內容

Excel SUMIF 功能

在Excel中,SUMIF函數可以幫助根據一個條件對單元格求和,本文將解釋該函數的語法並介紹一些使用SUMIF函數的示例。


 語法:

Excel中SUMIF函數的語法為:

=SUMIF (range, criteria, [sum_range])

 參數:

  • range:必填。 您要應用條件的單元格範圍。
  • criteria:必填。 用於確定需要添加哪些單元格的標準。 條件可以是文本,數字,日期,邏輯表達式,單元格引用或其他功能。
  • 備註:任何文本條件或包含數學符號的條件都必須用雙引號引起來。 如果條件是數字,則不需要雙引號。
  • sum_range:可選的。 這是相加的單元格範圍。 如果省略此參數,則使用range作為 總和範圍.

 返回:

返回基於特定條件的數字列表的總和。


 例子:

示例1:如果值大於,小於,等於或其他比較運算符,則求和

在Excel中,可以使用SUMIF函數將大於,小於,等於或不等於給定條件的值相加。

假設您有一個包含“名稱”,“數量”和“價格”列的表格,如下面的屏幕截圖所示,如何獲得數量大於250的總價格?

請將以下公式應用於空白單元格:

=SUMIF(B2:B8,">250",C2:C8)
  • 保養竅門:在以上公式中:
  • B2:B8:是要查找條件的單元格範圍。
  • "> 250“:”是您要對單元格值求和的基礎。
  • C2:C8:是要累加的範圍。

然後按 Enter 顯示數量大於250的總價格的關鍵,如下所示的屏幕截圖:

備註:您可以使用其他比較運算符,例如大於或等於(> =),小於(<),小於或等於(<=),等於(=),不等於(<>)您的需要。


示例2:帶有文本條件的SUMIF公式

如果要基於另一列中是否存在特定的文本值來對單元格值求和,SUMIF函數也可以幫您一個忙。


情況1:如果另一列中包含特定文本,則求和單元格值

以下面的數據為例,如果名稱為A列中的David,則獲取所有的總數量。

請輸入以下公式或將其複製到空白單元格中:

=SUMIF(A2:A8, "David", B2:B8)
  • 保養竅門:在以上公式中:
  • A2:A8:是要查找條件的單元格範圍。
  • “大衛”:是要對單元格值求和的條件。
  • B2:B8:是要累加的單元格範圍。

備註:您還可以使用單元格引用替換上面公式中的條件,如下所示: =SUMIF(A2:A8, D2, B2:B8).


情況2:求和單元格值不等於特定值

如果要在單元格不等於特定值時對單元格求和,例如,對除David之外的所有人員的總數求和,該怎麼辦?

請將以下公式應用於空白單元格:

=SUMIF(A2:A8, "<>David", B2:B8)
  • 保養竅門:在以上公式中:
  • A2:A8:是要查找條件的單元格範圍。
  • “ <> David”:是要對單元格值求和的條件。
  • B2:B8:是要累加的單元格範圍。

備註:您還可以使用單元格引用替換上面公式中的條件,如下所示: =SUMIF(A2:A8,"<>"&D2, B2:B8),則必須使用雙引號(“”)將比較運算符括起來,並使用與號(&)合併單元格引用。 看截圖:


示例3:帶通配符的SUMIF公式

有時,您可能需要根據部分文本匹配而不是完全匹配來對單元格值求和。 在這種情況下,可以將通配符星號(*)或問號(?)與SUMIF函數結合使用。

星號(*):代表任意數量的字符

問號(?):代表特定位置的任何單個字符


情況1:基於具有星號(*)字符的部分匹配的總和值

例如,我有一個表,如下面的屏幕快照所示,現在,我想對包含Kutools的產品的總訂單求和。

在這裡,請將以下公式應用於空白單元格:

=SUMIF(A2:A8, "*Kutools*", B2:B8)

然後,按 Enter 獲得以下結果的關鍵:

筆記:

1.如果您想對以Kutools開頭的單元格值求和,請使用以下公式: = SUMIF(A2:A8,“ Kutools *”,B2:B8).

2.如果列A中相應的單元格以文本Kutools結尾,則要對單元格值求和,請使用以下公式: = SUMIF(A2:A8,“ * Kutools”,B2:B8).

3.您還可以使用單元格引用來替換上面公式中的條件,如下所示: =SUMIF(A2:A8, "*"&D2&"*", B2:B8)。 您應該使用雙引號(“”)將星號括起來,並使用與號(&)來連接單元格引用。 看截圖:


情況2:帶有問號(?)的特定字符總數的值

如果要對列表中的單元格值求和,則相應的單元格長度恰好為5個字符,如下面的屏幕截圖所示。 您如何在Excel中解決此任務?

要處理此工作,您應該應用以下公式:

=SUMIF(A2:A8, "?????", B2:B8)

尖端:在此公式中:一個問號表示一個字符,五個問號表示5個字符。

然後,按 Enter 密鑰,您將獲得所需的結果:


示例4:求和對應於空白或非空白單元格的單元格值

在Excel中,SUMIF函數還可以幫助求和列表中相鄰單元格為空單元格或非空單元格的值。


情況1:如果相鄰單元格為空,則求和單元格值

請輸入以下任一公式或將其複製到要獲取結果的單元格中:

=SUMIF(A2:A8,"=",B2:B8)
=SUMIF(A2:A8,"",B2:B8)

然後,按 Enter 如果A列中有空白單元格,則要獲取總價結果的鍵,請參見屏幕截圖:


情況2:如果相鄰單元格為非空白單元格,則求和單元格值

如果您需要對相鄰單元格包含除空白單元格之外的文本的值求和,請應用以下公式:

=SUMIF(A2:A8,"<>",B2:B8)

然後,按 Enter 鍵,所有相鄰單元格中包含值的值都已加在一起,請參見屏幕截圖:


示例5:在Excel中具有日期的SUMIF

通常,您還可以使用SUMIF函數根據Excel中的特定日期對值求和。


情況1:如果日期是當前日期或小於當前日期,則求和

要匯總日期為當前日期的單元格值,可以使用以下公式:

=SUMIF(B2:B8, TODAY(), C2:C8)

然後,按 Enter 鍵,則將相應日期為今天的所有單元格相加。 看截圖:

筆記:

1.如果相應的日期小於或等於今天,則要對這些值求和,請使用以下公式: = SUMIF(B2:B8,“ <”&TODAY(),C2:C8).

2.如果對應的日期大於或等於今天,則要對這些值求和,請使用以下公式: = SUMIF(B2:B8,“>”&TODAY(),C2:C8).


情況2:兩個給定日期之間的總和

如果要對兩個給定日期之間的日期進行求和,可以將兩個SUMIF函數組合在一起以解決此任務。

請使用以下公式:

=SUMIF(B2:B8, ">=6/15/2019", C2:C8) - SUMIF(B2:B8, ">=7/31/2019", C2:C8)

然後,按Enter鍵,已計算出兩個給定日期之間的總值,請參見屏幕截圖:

備註:您還可以使用單元格引用替換上面公式中的條件,如下所示: = SUMIF(B2:B8,“> =”&E2,C2:C8)-SUMIF(B2:B8,“> =”&F2,C2:C8),請參見屏幕截圖:


示例6:Excel中多列的總和值

此SUMIF函數還可以幫助您根據一種條件對多列中的值求和。 例如,如果您現在擁有如下所示的一系列數據,以獲取四個月(一月,二月,三月和四月)的產品KTE的總值,該怎麼辦?

通常,SUMIF函數用於根據一個條件對一列值求和,對多個列中的值求和,您可以組合使用多個SUMIF函數來解決此任務。

請將以下公式應用於空白單元格:

=SUM(SUMIF(A2:A8,G2,B2:B8), SUMIF(A2:A8,G2,C2:C8), SUMIF(A2:A8,G2,D2:D8),SUMIF(A2:A8,G2,E2:E8))

然後按Enter鍵以獲得所需的正確結果,請參見屏幕截圖:

備註:如果需要匯總許多列,那麼上面的SUMIF函數將很難使用,因此在這裡,一個簡單的SUMPRODUCT函數也可以幫助您處理此工作。 請使用以下公式: =SUMPRODUCT((A2:A8=G2)*(B2:E8)),然後按 Enter 獲得結果的關鍵:

  • 保養竅門:在以上公式中:
  • A2:A8:是要查找條件的單元格範圍。
  • G2:是要對單元格值求和的條件。
  • B2:E8:是要累加的單元格範圍。


 更多SUMIF函數文章:

  • Excel中具有相同日期的對應值的總和
  • 您是否曾經嘗試過根據同一日期從Excel的另一列中求和相應的值? 假設我有以下數據范圍(A1:B13),A列是包含一些重複日期的日期範圍,B列具有訂單號,現在,我需要根據列中的同一日期將這些數字加在一起答:如何在Excel中快速輕鬆地完成它?
  • 在Excel中,Sumif日期小於/大於今天
  • 假設我們有一個銷售量表,其中包含每天的計劃量和實際量。 現在我們需要計算今天之前的發生日期,併計算今天之前的總計劃量,以便動態比較計劃量和實際量。 在這裡,我將應用SUMIF函數以在Excel中快速完成它。
  • 在Excel中具有一個或多個條件的Sumif
  • 在Excel中,基於一個或多個條件的求和值是我們大多數人的常見任務,SUMIF函數可以幫助我們根據一個條件快速求和,而SUMIFS函數可以幫助我們對多個條件求和。 本文,我將描述如何在Excel中對一個或多個條件求和?
  • 基於Excel中部分匹配的Sumif
  • 以下面的數據為例,當A列中包含部分“ KTE”文本時,我想對B列中的單元格值求和。如何實現? 本文,我將討論如何基於Excel工作表中的部分匹配來求和單元格值。

最佳辦公效率工具

Kutools for Excel-幫助您從人群中脫穎而出

🤖 Kutools 人工智慧助手:基於以下內容徹底改變數據分析: 智慧執行   |  生成代碼  |  建立自訂公式  |  分析數據並產生圖表  |  呼叫 Kutools 函數...
熱門特色: 尋找、突出顯示或識別重複項  |  刪除空白行  |  合併列或儲存格而不遺失數據  |  沒有公式的回合 ...
超VLookup: 多重標準  |  多重價值  |  跨多頁  |  模糊查詢...
副詞。 下拉清單: 簡易下拉列表  |  依賴下拉列表  |  多選下拉列表...
欄目經理: 新增特定數量的列  |  移動列  |  切換隱藏列的可見性狀態  將列與 選擇相同和不同的單元格 ...
特色功能: 網格焦點  |  設計圖  |  大方程式酒吧  |  工作簿和工作表管理器 | 資源庫 (自動文字)  |  日期選擇器  |  合併工作表  |  加密/解密單元格  |  按清單發送電子郵件  |  超級濾鏡  |  特殊過濾器 (過濾粗體/斜體/刪除線...)...
前 15 個工具集12 文本 工具 (添加文本, 刪除字符 ...)  |  50+ 圖表 類型 (甘特圖 ...)  |  40+ 實用 公式 (根據生日計算年齡 ...)  |  19 插入 工具 (插入二維碼, 從路徑插入圖片 ...)  |  12 轉化 工具 (數字到單詞, 貨幣兌換 ...)  |  7 合併與拆分 工具 (高級合併行, 拆分 Excel 儲存格 ...)  |  ... 和更多

Kutools for Excel 擁有超過 300 個功能, 確保只需點擊一下即可獲得您所需要的...

產品描述


Office選項卡-在Microsoft Office(包括Excel)中啟用選項卡式閱讀和編輯

  • 一秒鐘即可在數十個打開的文檔之間切換!
  • 每天為您減少數百次鼠標單擊,告別鼠標手。
  • 查看和編輯多個文檔時,將您的工作效率提高 50%。
  • 為 Office(包括 Excel)帶來高效的選項卡,就像 Chrome、Edge 和 Firefox 一樣。
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations