Skip to main content

Kutools for Office — 一套工具,五種功能。完成更多工作。

從文字字串中刪除或去除數字字符

Author Xiaoyang Last modified

如果您想從一組文字字串中僅刪除所有數字,但保留其他非數字字符,也許 Excel 中的一些公式可以幫助您。

doc-remove-numbers-1


在 Excel 中從文字字串中刪除或去除所有數字

若要僅從字母數字字串中刪除數字,一個結合了 TEXTJOIN、MID、ROW、IF、ISERR、LEN 和 INDIRECT 函數的複雜陣列公式可以幫助您。注意:此公式僅在 Excel 2019 和 Office 365 中運行良好。通用語法為:

=TEXTJOIN("",TRUE,IF(ISERR(MID(text,ROW(INDIRECT("1:"&LEN(text))),1)+0),MID(text,ROW(INDIRECT("1:"&LEN(text))),1),""))
  • text: 您想要刪除所有數字的文字字串或單元格值。

1. 請將以下公式複製或輸入到您希望輸出結果的空白單元格中:

=TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""))

2. 然後,同時按下 Ctrl + Shift + Enter 鍵以獲得第一個結果,請參見截圖:

doc-remove-numbers-2

3. 接著,選擇公式單元格,向下拖動填充柄至您想使用的單元格,所有數字都已從文字字串中被刪除了,請參見截圖:

doc-remove-numbers-3


公式的解釋:

ROW(INDIRECT("1:"&LEN(A2))):INDIRECT 函數位於 ROW 函數內,將返回與單元格 A2 長度相同的陣列列表,如下所示,這部分被視為 MID 函數中的 start_num。
{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21}

MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1):這個 MID 函數用於從單元格 A2 提取文字以獲取一個字符,並會返回如下陣列:
{ "5";"0";"0";" ";"K";"u";"t";"o";"o";"l";"s";" ";"f";"o";"r";" ";"E";"x";"c";"e";"l"}

MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0: 在該陣列後添加 0 值是為了強制將文本轉換為數字,數字文本值將被轉換為數字,而非數字值則會顯示為 #VALUE 錯誤值,如下所示:
{"5";"0";"0";#VALUE!;#VALUE!;#VALUE!;#VALUE!;#VALUE!;#VALUE! !;#VALUE! !;#VALUE!...}

IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""):IF 函數用於檢查由 MID 函數返回的陣列是否為錯誤值。如果是錯誤值,則使用第二個 MID 函數獲取非數字字符,否則顯示空字符串,如下所示:
{ "";"";"";" ";"K";"u";"t";"o";"o";"l";"s";" ";"f";"o";"r";" ";"E";"x";"c";"e";"l"}

TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")):最後,TEXTJOIN 函數將連接所有值並忽略空字符串以獲得結果。


注意事項:

1. 在刪除數字字符時,可能會留下一些額外的空格字符,要刪除所有多餘的空格,應該將公式包裹在 TRIM 函數中,如下所示:

=TRIM(TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")))

2. 若要在早期版本的 Excel 中從文字字串中刪除數字,請應用以下公式:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,1,""),2,""),3,""),4,""),5,""),6,""),7,""),8,""),9,""),0,"")

doc-remove-numbers-4


相關函數:

  • TEXTJOIN
  • TEXTJOIN 函數使用特定分隔符將一行、一列或一個範圍內的多個值連接起來。
  • MID
  • MID 函數用於查找並返回給定文字字串中間的特定數量的字符。
  • ROW
  • Excel 的 ROW 函數返回引用的行號。
  • INDIRECT
  • Excel 的 INDIRECT 函數將文字字串轉換為有效的引用。
  • LEN
  • LEN 函數返回文字字串中的字符數。
  • IF
  • IF 函數執行簡單的邏輯測試,根據比較結果返回一個值,如果結果為 TRUE,則返回一個值;如果結果為 FALSE,則返回另一個值。
  • ISERR
  • ISERR 函數用於對任何錯誤類型(#N/A 錯誤除外)返回 TRUE。

更多文章:

  • 從 Excel 單元格中刪除換行符
  • 本教程提供了三個公式,幫助您刪除特定單元格中的換行符(這些換行符是由在單元格中按下 Alt + Enter 鍵產生的)。

最強大的辦公生產力工具

Kutools for Excel - 幫助您脫穎而出

🤖 KUTOOLS AI 助手:基於智能執行生成代碼創建自訂公式分析數據並生成圖表調用 Kutools 函數等進行數據分析革命
熱門功能查找、標記或識別重複值  |  刪除空行  |  合併列或儲存格而不丟失數據  |  無需公式即可四捨五入 ...
超級 VLookup多條件  |  多值  |  跨多工作表  |  模糊查找...
高級下拉列表簡易下拉列表  |  依賴下拉列表  |  多選下拉列表...
列管理器添加特定數量的列  |  移動列  |  切換隱藏列的可見性狀態  比較列以 選擇相同和不同的儲存格 ...
特色功能網格聚焦  |  設計檢視  |  增強編輯欄  |  工作簿與工作表管理器 | 資源庫(自動文字)  |  日期提取器  |  合併資料  |  加密/解密儲存格  |  按列表發送電子郵件  |  超級篩選  |  特殊篩選(篩選粗體/斜體/刪除線...) ...
前 15 大工具集12 文本工具添加文本刪除特定字符 ...)  |  50+ 圖表 類型甘特圖 ...)  |  40+ 個實用公式基於生日計算年齡 ...)  |  19 插入工具插入QR碼從路徑插入圖片 ...)  |  12 轉換工具金額轉大寫匯率轉換 ...)  |  7 個合併與分割工具高級合併行拆分Excel儲存格 ...)  |  ... 及更多
使用您偏好的語言來操作 Kutools - 支持英文、西班牙文、德文、法文、中文及其他 40 多種語言!

Kutools for Excel 擁有超過 300 種功能,確保您需要的功能只需輕點一下即可實現...


Office Tab - 在 Microsoft Office(包括 Excel)中啟用標籤式閱讀和編輯

  • 一秒鐘內在數十個打開的文件之間切換!
  • 每天減少數百次鼠標點擊,告別滑鼠手。
  • 當查看和編輯多個文檔時,您的效率提高了 50%。
  • 為 Office(包括 Excel)帶來高效的標籤,就像 Chrome、Edge 和 Firefox 一樣。