在 Excel 儲存格中於特定字元處拆分文字字串

本教學說明如何在 Excel 中，於特定字元處將文字字串拆分至個別欄位的公式。

如何在 Excel 儲存格中，於特定字元的位置拆分文字字串？

假設您在 B 欄中有一份文字字串清單（如下方截圖所示），並希望在「——」字元處將文字拆分，再將結果分別輸出至三個獨立欄位。此時，下列公式即可協助您輕鬆達成目標。

通用公式

拆分左側文字的通用公式

=LEFT(text_string,FIND("Char", text_string)-1)

拆分中間文字的通用公式

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

拆分右側文字的通用公式

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

上述公式的參數說明

如何運用這些公式？

首先，根據特定字元拆分第一段文字字串

1. 選取一個空白儲存格來輸出結果，此處我選擇 C3.

2. 在儲存格中輸入下方公式，然後按下 Enter 鍵；接著向下拖曳已套用 LEFT 公式的儲存格，即可快速套用至其他儲存格。

=LEFT(B3,FIND("-",B3)-1)

其次，根據特定字元拆分中間文字字串

1. 選取一個空白儲存格（例如 D3）來輸出結果。

2. 在儲存格中輸入下方公式，然後按下 Enter 鍵；接著選取結果儲存格，向下拖曳填滿控點，即可將公式套用至其他儲存格。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

最後，根據特定字元拆分最後一段文字字串

1. 選取一個空白儲存格（例如 E3）來顯示結果。

2. 在其中輸入下方公式，然後按下按下鍵。選取結果儲存格，向下拖曳填滿控點，即可將公式套用至其他儲存格。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

現在，B 欄每個儲存格中的文字字串都已成功拆分為三個部分。

提示：若您只想依特定字元將文字字串拆分為兩部分，可在使用上述 LEFT 公式取得第一部分後，套用下方的 RIGHT 公式來提取第二部分（如下方截圖所示）。

=RIGHT(B3,LEN(B3)-FIND("-",B3))

這些公式是如何運作的？

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)FIND 函數會傳回文字字串「KTE-Jan-359」中第一個「-」字元的起始位置，結果為 4.
• LEFT(B3,4-1)：LEFT 函數從文字字串 KTE-Jan-359 的左側提取 3 個字元（4−1＝3），結果為 KTE。
  注意：由於第一個「——」位於文字字串的第 4 個位置，需減去 1 才能排除該字元。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1：FIND 函數會傳回文字字串 KTE-Jan-359 中字元「-」的起始位置，此處結果為 4.
  注意：由於第一個「-」位於文字字串的第 4 個位置，需將 1 加到 4 上，才能從該字元後開始提取文字，最終得到 4+1=5.
• FIND("-",B3,FIND("-",B3)+1) 此處顯示為 FIND("-", "KTE-Jan-359", 4+1)：FIND 函數會從「KTE-Jan-359」的第 5 個字元開始搜尋「-」的位置，並傳回結果 8.
• MID(B3, 5, 8 - 4 - 1)MID(KTE-Jan-359,5,3) 表示 MID 函數會從文字字串「KTE-Jan-359」的第 5 個字元開始，提取連續 3 個字元，結果為「Jan」。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)LEN 函數會計算文字字串「KTE-Jan-359」的總長度，並傳回結果 11.
• FIND("-",B3,FIND("-",B3)+1)Find 函數會從 KTE-Jan-359 的第 5 個字元開始搜尋「-」的位置，並傳回結果 8.
• RIGHT(B3,11 - 8))RIGHT 函數會從「KTE-Jan-359」的右側提取 3 個字元（11 減 8），結果為「359」。

相關函數

相關公式