將尺寸拆分為個別的長度、高度與寬度

本文說明如何將儲存格中的尺寸拆分為三個獨立部分：長度、高度與寬度。

如何將尺寸拆分為三個部分？

若要將尺寸拆分為個別的長度、高度與寬度，您需分別套用三個不同的公式。

提取第一個尺寸的通用公式

=LEFT(text,FIND("char",text)-1)

提取第二個尺寸的通用公式

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

提取第三個尺寸的通用公式

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

上述公式的引數

如何運用這些公式？

首先，我們需要取得第一個尺寸。

1. 選取一個空白儲存格，用來輸出第一個尺寸。

2. 在儲存格中輸入下列公式，然後按下 Enter 先按鍵；接著選取結果儲存格，並拖曳填滿控點，即可依需求快速將公式套用至其他儲存格！

=LEFT(B5,FIND("x",B5)-1)

接著，我們將依照下列步驟拆分第二個尺寸。

1. 選取一個空白儲存格，用來輸出第二個尺寸。

2. 在其中輸入下方公式，然後按下 Enter 鍵。選取結果儲存格並拖曳填滿控點，即可依需求將公式套用至其他儲存格。

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

最後，取得第三個尺寸

1. 選取一個空白儲存格，用以輸出最後一個尺寸。

2. 在其中輸入下方公式，然後按下 Enter 鍵。選取結果儲存格後，拖曳填滿控點，即可依需求將公式套用至其他儲存格。

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

這些公式是如何運作的？

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1：FIND 函數用於取得 B5 中第一個「x」的位置。若要提取不含該「x」的前段尺寸，需將結果減去 1，因此計算為 4-1=3.
2. LEFT(B5,3)：LEFT 函數從 B5 左側提取前 3 個字元，即可取得結果「100」。

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1FIND 函數用來定位 B5 中第一個「x」的位置。由於您需要取得第一個「x」之後的第二個尺寸，因此必須在此結果上加 1，最終得出 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2)：SUBSTITUTE 函數將 B5 中第二個「x」替換為「@」，並傳回結果 100x 50@300；
• FIND("@",100x 50@300) 此處的 FIND 函數用於找出文字「100x 50@300」中「@」字元的位置，並傳回結果 7.

3. (FIND("x",B5)+1)：如步驟 1 所述，此處 FIND 函數會定位 B5 中第一個「x」的位置，並加 1 得到結果 5.
4. MID(B5,5,7-(5))：MID 函數從 B5 文字的第 5 個字元開始，提取 2 個字元（7－5＝2），最終傳回結果 50.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5)：LEN 函數計算 B5 中的總根據字串長度篩選數，並傳回結果 10；
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2)：SUBSTITUTE 函數將 B5 中第二個「x」替換為「@」，並傳回結果 100x 50@300；
• FIND("@",100x 50@300) 此處的 FIND 函數會在文字「100x 50@300」中定位「@」符號，並傳回結果 7.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2))：（10-7）計算 B5 儲存格中文字字串的總長度減去前 7 個字元，結果傳回 3.
4. RIGHT(B5,3)：接著，RIGHT 函數從 B5 右側提取 3 個字元，傳回第三個尺寸「300」。

相關函數

相關公式