Skip to main content

從文字字串中刪除特定字符前或後的文本

Author: Xiaoyang Last Modified: 2025-08-06

本教程將介紹如何從Excel中的文字字串列表中刪除特定字符（例如空格、逗號）之前或之後的文本。

doc-remove-after-first-space-01

從文字字串中刪除第一個特定字符前或後的文本

刪除第一個特定字符（例如空格、逗號）之前的文本

要從文字字串中刪除第一個特定字符之前的文本，RIGHT、LEN 和 FIND 函數可以幫助您，通用語法為：

=RIGHT(單元格, LEN(單元格)-FIND("char", 單元格))
  • 單元格: 您希望刪除文本的單元格引用或文字字串。
  • char: 您希望根據其刪除文本的特定分隔符。

請在您希望輸出結果的空白單元格中輸入或複製以下公式：

=RIGHT(A2,LEN(A2)-FIND(" ",A2))

然後，向下拖動填充柄以應用此公式到其他單元格，並且所有第一個空格之前的文本都已從文字字串中刪除，請參見截圖：

doc-remove-after-first-space-02

公式解釋：

1.LEN(A2)-FIND(" ",A2): 這部分公式被識別為 RIGHT 函數中的 num_chars。

  • FIND(" ",A2): FIND 函數用於獲取第一個空格的位置，它返回數字 11。
  • LEN(A2): 此 LEN 函數將返回單元格 A2 中字符的總數。它將獲得數字 27。
  • LEN(A2)-FIND(" ",A2)=27-11: 從單元格 A2 的總長度中減去第一個空格的位置，將得到第一個空格之後的字符數量。

2. RIGHT(A2,LEN(A2)-FIND(" ",A2))=RIGHT(A2, 16): 最終，此 RIGHT 函數將從單元格 A2 文字字串的右側提取 16 個字符。

刪除第一個特定字符（例如空格、逗號）之後的文本

在 Excel 中，結合 LEFT 和 FIND 函數，您可以快速刪除第一個特定字符之後的文本。通用語法為：

=LEFT(單元格,FIND("char",單元格)-1)
  • 單元格: 您希望刪除文本的單元格引用或文字字串。
  • char: 您希望根據其刪除文本的特定分隔符。

請在空白單元格中應用以下公式：

=LEFT(A2,FIND(" ",A2)-1)

然後，向下拖動填充柄以應用此公式到其他單元格，並且所有第一個空格之後的文本都已立即刪除，請參見截圖：

doc-remove-after-first-space-03

公式解釋：

1.FIND(" ",A2)-1: 此 FIND 函數將獲取單元格 A2 中第一個空格的位置，減去 1 表示排除空格字符。它將得到結果 10。它被識別為 LEFT 函數中的 num_chars。

2. LEFT(A2,FIND(" ",A2)-1)=LEFT(A2, 10): 此 LEFT 函數將從單元格 A2 文字字串的左側提取 10 個字符。

從文字字串中刪除最後一個特定字符前或後的文本

刪除最後一個特定字符（例如空格、逗號）之前的文本

如果您需要刪除最後一個特定字符之前的所有文本，並僅保留最後一個特定字符之後的子字符串，則 RIGHT、LEN、SEARCH 和 SUBSTITUTE 函數可能會對您有所幫助。通用語法為：

=RIGHT(單元格,LEN(單元格)-SEARCH("#",SUBSTITUTE(單元格,"char","#",LEN(單元格)-LEN(SUBSTITUTE(單元格,"char","")))))
  • 單元格: 您希望刪除文本的單元格引用或文字字串。
  • char: 您希望根據其刪除文本的特定分隔符。

要解決此任務，請將以下公式複製或輸入到空白單元格中：

=RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))

然後，拖動填充柄以將此公式填充到其他需要的單元格，現在，最後一個空格之前的所有文本都已被刪除，僅保留最後一個空格之後的文本，請參見截圖：

doc-remove-after-first-space-04

公式解釋：

1. LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))):

  • SUBSTITUTE(A2," ",""): 此 SUBSTITUTE 函數用於將單元格 A2 中的所有空格字符替換為無內容，您將得到如下結果：“Tom-Grade1HoustonTexasUS”。
  • LEN(SUBSTITUTE(A2," ",""): 此 LEN 函數返回由 SUBSTITUTE 函數返回的文字字串的字符數量（不包含空格）。它將得到數字 24。
  • LEN(A2)-LEN(SUBSTITUTE(A2," ","")=27-24: 從單元格 A2 的總長度中減去沒有空格的字符數量，將得到文字字串之間的空格數量。這將得到數字 3。
  • SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))= SUBSTITUTE(A2," ","#", 3): 此 SUBSTITUTE 函數用於將最後一個空格字符替換為特定的 # 字符，結果是：“Tom-Grade1 Houston Texas#US”。
  • SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))= SEARCH("#", "Tom-Grade1 Houston Texas#US") : 此 SEARCH 函數將查找由 SUBSTITUTE 函數返回的文字字串中特定 # 字符的位置。它將得到數字 25。
  • LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))=27-25: 單元格 A2 中文本的總長度減去最後一個空格的位置，將得到最後一個空格之後的字符數量。這將得到數字 2。

2. RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))=RIGHT(A2, 2): 最終，此 RIGHT 函數將從單元格 A2 文字字串的右側提取 2 個字符。

刪除最後一個特定字符（例如空格、逗號）之後的文本

要刪除最後一個特定字符之後的文本，LEFT、FIND、SUBSTITUTE 和 LEN 函數可以幫助您，通用語法為：

=LEFT(單元格,FIND("#",SUBSTITUTE(單元格,"char","#",LEN(單元格)-LEN(SUBSTITUTE(單元格,"char",""))))-1)
  • 單元格: 您希望刪除文本的單元格引用或文字字串。
  • char: 您希望根據其刪除文本的特定分隔符。

請在空白單元格中輸入或複製以下公式：

=LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)

然後，向下拖動填充柄以應用此公式到其他單元格，您將得到如下截圖所示的結果：

doc-remove-after-first-space-05

公式解釋：

1. FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1:

  • SUBSTITUTE(A2," ",""): 此 SUBSTITUTE 函數用於將單元格 A2 中的所有空格字符替換為無內容，您將得到如下結果：“Tom-Grade1HoustonTexasUS”。
  • LEN(SUBSTITUTE(A2," ",""): 此 LEN 函數返回由 SUBSTITUTE 函數返回的文字字串的字符數量（不包含空格）。它將得到數字 24。
  • LEN(A2)-LEN(SUBSTITUTE(A2," ",""))=27-24: 從單元格 A2 的總長度中減去沒有空格的字符數量，將得到文字字串之間的空格數量。這將得到數字 3。
  • SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))= SUBSTITUTE(A2," ","#", 3): 此 SUBSTITUTE 函數用於將最後一個空格字符替換為特定的 # 字符，結果是：“Tom-Grade1 Houston Texas#US”。
  • FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1=FIND("#", "Tom-Grade1 Houston Texas#US ")-1=25-1: 此 FIND 函數將返回由 SUBSTITUTE 函數返回的文字字串中特定 # 字符的位置，減去 1 表示排除空格字符。這將得到數字 24。

2. LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)=LEFT(A2, 24): 最終，此 LEFT 函數用於從單元格 A2 文字字串的左側提取 24 個字符。

相關函數使用：

  • LEFT:
  • LEFT 函數從提供的字串左側提取指定數量的字符。
  • RIGHT:
  • RIGHT 函數用於從文字字串的右側提取指定數量的字符。
  • FIND:
  • FIND 函數用於在另一個字串中查找字串，並返回該字串在另一個字串中的起始位置。
  • SEARCH:
  • SEARCH 函數可幫助您從給定的文字字串中查找特定字符或子字串的位置。
  • SUBSTITUTE:
  • Excel 的 SUBSTITUTE 函數將文字字串中的文本或字符替換為其他文本或字符。
  • LEN:
  • LEN 函數返回文字字串中的字符數量。

更多文章：

最佳的辦公生產力工具

Kutools for Excel - 幫助您脫穎而出

🤖 KUTOOLS AI 助手：基於以下方式徹底改變數據分析：智能執行   |  生成代碼  |  創建自訂公式  |  分析數據並生成圖表  |  調用 KUTOOLS 函數…
熱門功能： 查找、標記或標識重複值  |  刪除空行  |  合併列或單元格而不丟失數據  |  無需公式四捨五入 ...
超級 VLookup：多條件  |  多值  |  跨多工作表  |  模糊查找...
高級下拉列表：簡易下拉列表  |  依賴下拉列表  |  多選下拉列表...
列管理器：添加特定數量的列  |  移動列  |  切換隱藏列的可見狀態  |  比較列以選擇相同和不同的單元格 ...
特色功能：網格聚焦  |  設計檢視  |  增強編輯欄  |  工作簿與工作表管理器 | 資源庫 (自動文字)  |  日期提取器  |  合併資料  |  加密/解密單元格  |  按清單發送電子郵件  |  超級篩選  |  特殊篩選（篩選粗體/斜體/刪除線...） ...
頂級 15 個工具集:  12 個文本工具（添加文本，刪除特定字符 ...)  |  50+ 種圖表 類型（甘特圖 ...)  |  40+ 實用 公式（基於生日計算年齡 ...)  |  19 個插入工具（插入QR碼，從路徑插入圖片 ...)  |  12 個轉換工具（金額轉大寫，匯率轉換 ...)  |  7 個合併與分割工具（高級合併行，拆分Excel單元格 ...)  |  ... 及更多
使用您偏好的語言來操作 Kutools——支持英語、西班牙語、德語、法語、中文等 40 多種語言！

Kutools for Excel 擁有超過 300 項功能，確保您需要的功能只需一鍵即可觸及...

Office Tab - 在 Microsoft Office（包括 Excel）中啟用多標籤閱讀和編輯

  • 一秒鐘內在數十個打開的文檔之間切換！
  • 每天為您減少數百次鼠標點擊，告別滑鼠手。
  • 在查看和編輯多個文檔時，提升您的效率達 50%。
  • 為 Office（包括 Excel）帶來高效的標籤功能，就像 Chrome、Edge 和 Firefox 一樣。