尋找缺失值

有時候，您需要比較兩個清單，檢查 Excel 中的 A 清單中的值是否在 B 清單中。例如，您有一個產品清單，並且想要檢查您的清單中的產品是否出現在供應商提供的產品清單中。為了完成此任務，我們列出了以下三種方法，您可以選擇您喜歡的方法。

使用 MATCH、ISNA 和 IF 尋找缺失值
使用 VLOOKUP、ISNA 和 IF 尋找缺失值
使用 COUNTIF 和 IF 尋找缺失值

使用 MATCH、ISNA 和 IF 尋找缺失值

要找出您的清單中的所有產品是否都存在於供應商的清單中（如上面的截圖所示），您可以首先使用 MATCH 函數來獲取您清單中的某個產品（A 清單的值）在供應商清單（B 清單）中的位置。如果找不到該產品，MATCH 會返回 #N/A 錯誤。然後，您可以將結果傳遞給 ISNA，將 #N/A 錯誤轉換為 TRUE，這意味著這些產品是缺失的。接著，IF 函數將返回您期望的結果。

通用語法

=IF(ISNA(MATCH("查找值",查找範圍,0)),"缺失","找到")

√ 注意：您可以根據需要更改 "缺失"、"找到" 為任何其他值。

要找出您的清單中的所有產品是否都存在於供應商的清單中，請將以下公式複製或輸入到 H6 單元格中，然後按Enter鍵以獲得結果：

=IF(ISNA(MATCH(30002,$B$6:$B$10,0)),"缺失","找到")

或者，使用單元格引用使公式動態化：

=IF(ISNA(MATCH(G6,$B$6:$B$10,0)),"缺失","找到")

√ 注意：上面的美元符號 ($) 表示絕對引用，這意味著當您將公式移動或複製到其他單元格時，公式中的 lookup_range 不會改變。但是，由於您希望 lookup_value 是動態的，因此不會添加美元符號。輸入公式後，向下拖動填充柄以將公式應用於下方的單元格。

公式的解釋

這裡我們以下面的公式為例：

=IF(ISNA(MATCH(G8,$B$6:$B$10,0)),"缺失","找到")

• MATCH(G8,$B$6:$B$10,0): match_type 0 強制 MATCH 函數返回一個數字值，表示在陣列 $B$6:$B$10 中第一次匹配 3004 的位置，該值位於 G8 單元格中。然而，在這種情況下，MATCH 找不到該值在查找陣列中，因此它將返回 #N/A 錯誤。
• ISNA(ISNA(MATCH(G8,$B$6:$B$10,0))) = ISNA(ISNA(#N/A)): ISNA 用於檢查某個值是否為“#N/A”錯誤。如果是，函數將返回 TURE；如果該值不是“#N/A”錯誤，則返回 FALSE。因此，這個 ISNA 公式將返回 TURE。
• IF(ISNA(MATCH(G8,$B$6:$B$10,0)),"缺失","找到") = IF(TRUE,"缺失","找到"): 如果 ISNA 和 MATCH 的比較結果為 TRUE，IF 函數將返回 缺失，否則將返回 找到。因此，公式將返回 缺失。

使用 VLOOKUP、ISNA 和 IF 尋找缺失值

要找出您的清單中的所有產品是否都存在於供應商的清單中，您可以將上述的 MATCH 函數替換為 VLOOKUP，因為它的功能與 MATCH 相同，即如果值不存在於另一個清單中，它將返回 #N/A 錯誤，或者我們可以說它是缺失的。

通用語法

=IF(ISNA(VLOOKUP("查找值",查找範圍,1,FALSE)),"缺失","找到")

√ 注意：您可以根據需要更改 "缺失"、"找到" 為任何其他值。

要找出您的清單中的所有產品是否都存在於供應商的清單中，請將以下公式複製或輸入到 H6 單元格中，然後按 Enter 鍵以獲得結果：

=IF(ISNA(VLOOKUP(30002,$B$6:$B$10,1,FALSE)),"缺失","找到")

或者，使用單元格引用使公式動態化：

=IF(ISNA(VLOOKUP(G6,$B$6:$B$10,1,FALSE)),"缺失","找到")

√ 注意：上面的美元符號 ($) 表示絕對引用，這意味著當您將公式移動或複製到其他單元格時，公式中的 lookup_range 不會改變。但是，由於您希望 lookup_value 是動態的，因此不會添加美元符號。輸入公式後，向下拖動填充柄以將公式應用於下方的單元格。

公式的解釋

這裡我們以下面的公式為例：

=IF(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE)),"缺失","找到")

• VLOOKUP(G8,$B$6:$B$10,1,FALSE): range_lookup FALSE 強制 VLOOKUP 函數查找並返回完全匹配 3004 的值，該值位於 G8 單元格中。如果 lookup_value 3004 存在於陣列 $B$6:$B$10 的第 1 列中，VLOOKUP 將返回該值；否則，它將返回 #N/A 錯誤值。這裡，3004 不存在於陣列中，因此結果將是 #N/A。
• ISNA(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE))) = ISNA(ISNA(#N/A)): ISNA 用於檢查某個值是否為“#N/A”錯誤。如果是，函數將返回 TURE；如果該值不是“#N/A”錯誤，則返回 FALSE。因此，這個 ISNA 公式將返回 TURE。
• IF(ISNA(VLOOKUP(G8,$B$6:$B$10,1,FALSE)),"缺失","找到") = IF(TRUE,"缺失","找到"): 如果 ISNA 和 VLOOKUP 的比較結果為 TRUE，IF 函數將返回 缺失，否則將返回 找到。因此，公式將返回 缺失。

使用 COUNTIF 和 IF 尋找缺失值

要找出您的清單中的所有產品是否都存在於供應商的清單中，您可以使用更簡單的公式，結合 COUNTIF 和 IF 函數。該公式利用了 Excel 會將任何非零數字評估為 TRUE 的事實。因此，如果值存在於另一個清單中，COUNTIF 函數將返回該值在該清單中的出現次數，然後 IF 將該數字視為 TRUE；如果該值不存在於清單中，COUNTIF 函數將返回 0，而 IF 將其視為 FALSE。

通用語法

=IF(COUNTIF("查找範圍",查找值),"找到","缺失")

√ 注意：您可以根據需要更改 "找到"、"缺失" 為任何其他值。

要找出您的清單中的所有產品是否都存在於供應商的清單中，請將以下公式複製或輸入到 H6 單元格中，然後按 Enter 鍵以獲得結果：

=IF(COUNTIF($B$6:$B$10,30002),"找到","缺失")

或者，使用單元格引用使公式動態化：

=IF(COUNTIF($B$6:$B$10,G6),"找到","缺失")

√ 注意：上面的美元符號 ($) 表示絕對引用，這意味著當您將公式移動或複製到其他單元格時，公式中的 lookup_range 不會改變。但是，由於您希望 lookup_value 是動態的，因此不會添加美元符號。輸入公式後，向下拖動填充柄以將公式應用於下方的單元格。

公式的解釋

這裡我們以下面的公式為例：

=IF(COUNTIF($B$6:$B$10,G8),"找到","缺失")

• COUNTIF($B$6:$B$10,G8): COUNTIF 函數計算 G8 單元格中的值 3004 在陣列 $B$6:$B$10 中出現了多少次。顯然，3004 不存在於陣列中，因此結果將是 0。
• IF(COUNTIF($B$6:$B$10,G8),"找到","缺失") = IF(0,"找到","缺失"): IF 函數將 0 評估為 FALSE。因此，公式將返回 缺失，這是第一個參數評估為 FALSE 時返回的值。

相關函數

相關公式