Skip to main content

從文字字串中提取第一個和第二個逗號之間的文字

Author: Xiaoyang Last Modified: 2025-05-12

要從文字字串中提取第一個和第二個逗號或第二個和第三個逗號之間的文字，本教程將介紹一些在 Excel 中解決此任務的公式。

doc-extract-text-between-two-commas-1

從文字字串中提取第一個和第二個逗號或其他分隔符之間的文字

如果你想提取第一個和第二個逗號或其他分隔符之間的文字，MID 和 SEARCH 函數可以幫助你完成這個工作，通用語法是：

=MID(單元格, SEARCH("字符",單元格) + 1, SEARCH("字符",單元格, SEARCH("字符",單元格)+1) - SEARCH("字符",單元格) - 1)
  • 單元格：你想提取文字的單元格引用或文字字串。
  • 字符：你想根據其提取文字的特定分隔符。

請將以下公式複製或輸入到你想獲取結果的空白單元格中：

=MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)

然後，向下拖動填充柄以應用該公式到其他單元格，所有位於第一個和第二個逗號之間的文字都已提取出來，請參見截圖：

doc-extract-text-between-two-commas-2

公式的解釋：

1. SEARCH(",",A2) + 1：這個 SEARCH 函數用於查找 A2 單元格中第一個逗號的位置，加 1 表示從下一個字符開始提取。它將得到數字 14。這部分被識別為 MID 函數中的 start_num 參數。

2. SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) – 1：這部分被識別為 MID 函數中的 num_chars 參數。

  • SEARCH(",",A2,SEARCH(",",A2)+1)：這部分公式用於獲取第二個逗號的位置，它將得到數字 21。
  • SEARCH(",", A2)：這個 SEARCH 函數將獲取 A2 單元格中第一個逗號的位置。它將得到數字 13。
  • SEARCH(",", A2, SEARCH(",", A2)+1) - SEARCH(",", A2)-1=21-13-1：從第二個逗號的位置減去第一個逗號的位置，然後再減去 1，表示排除逗號字符。結果是 7。

3. MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)=MID(A2, 14, 7)：最後，MID 函數將從 A2 單元格的第十四個字符開始提取 7 個字符。

注意：

1. 如果你的文字字串由其他分隔符分隔，你只需根據需要更改公式中的逗號為其他分隔符即可。

2. 這裡還有一個簡單的公式也可以幫到你：

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),100,100))

doc-extract-text-between-two-commas-3

從文字字串中提取第二個和第三個逗號或其他分隔符之間的文字

有時，你可能需要提取第二個和第三個逗號之間的文字，在這種情況下，MID、FIND 和 SUBSTITUTE 函數的組合可以幫助你。通用語法是：

=MID(單元格, FIND("#",SUBSTITUTE(單元格,"字符","#",2))+1, FIND("#",SUBSTITUTE(單元格,"字符","#",3)) - FIND("#",SUBSTITUTE(單元格,"字符","#",2))-1)
  • 單元格：你想提取文字的單元格引用或文字字串。
  • 字符：你想根據其提取文字的特定分隔符。

請將以下公式複製或輸入到空白單元格中：

=MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1)

粘貼公式後，向下拖動填充柄以應用該公式到其他單元格，所有位於第二個和第三個逗號之間的文字都已提取出來，如下截圖所示：

doc-extract-text-between-two-commas-4

公式的解釋：

1. FIND("#",SUBSTITUTE(A2,",","#",2))+1：這部分被識別為 MID 函數中的 start_num 參數。

  • SUBSTITUTE(A2,",","#",2)：這個 SUBSTITUTE 函數用於將 A2 單元格中的第二個逗號替換為 # 字符，你將得到這樣的結果："Apple-3000KG,Houston#Texas,US"。
  • FIND("#",SUBSTITUTE(A2,",","#",2))+1：使用 FIND 函數獲取由 SUBSTITUE 函數返回的文字字串中 # 字符的位置。加 1 表示從下一個字符開始提取。這將得到數字 22。

2. FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1：這部分被識別為 MID 函數中的 num_chars 參數。

  • FIND("#",SUBSTITUTE(A2,",","#",3))：這個公式將返回第三個逗號的位置，它將得到數字 27。
  • FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1= 27-21-1：從第三個逗號的位置減去第二個逗號的位置，然後再減去 1，表示排除逗號字符。結果是 5。

3. MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1) = MID(A2, 22, 5)：最後，MID 函數將從 A2 單元格的第二十二個字符開始提取 5 個字符。

注意：

1. 如果你的文字字串由其他分隔符分隔，你只需根據需要更改公式中的逗號為其他分隔符即可。

2. 另一個簡單的公式也可以幫助你提取第二個和第三個逗號之間的文字：

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),200,100))

doc-extract-text-between-two-commas-5

相關函數：

  • MID：
  • MID 函數用於從給定的文字字串中間找到並返回特定數量的字符。
  • FIND：
  • FIND 函數用於在另一個字串中查找字串，並返回該字串在另一個字串中的起始位置。
  • SEARCH：
  • SEARCH 函數可以幫助你從給定的文字字串中查找特定字符或子字串的位置。
  • SUBSTITUTE：
  • Excel 的 SUBSTITUTE 函數用於替換文字字串中的文本或字符。

更多文章：

  • 從單元格中提取多行文字
  • 如果你有一列包含換行符（在輸入文本時按下 Alt + Enter 鍵產生）分隔的文字字串，現在你想將這些行的文字提取到多個單元格中，如下截圖所示。如何使用 Excel 中的公式來解決這個問題？
  • 從文字字串中提取括號內的文字
  • 如果文字字串中有部分文字被括號包圍，現在你需要提取括號內的所有文字，如下截圖所示。如何快速輕鬆地在 Excel 中解決這個問題？
  • 提取特定字符最後一次出現後的文字
  • 如果你有一列包含多個分隔符的複雜文字字串（例如以下截圖，其中包含連字符、逗號、空格等），現在你想找到連字符最後一次出現的位置，然後提取其後的子字串。本文將介紹一些處理此任務的公式。

最佳的辦公生產力工具

Kutools for Excel - 幫助您脫穎而出

? Kutools AI 助手：基於智能執行、生成代碼、創建自訂公式、分析數據並生成圖表、調用 Kutools 函數…來徹底改變數據分析方式。
熱門功能：查找、標記或識別重複值  |  刪除空行  |  合併列或單元格而不丟失數據  |  四捨五入無需公式 ...
超級 VLookup：多條件  |  多值  |  跨多工作表  |  模糊查找...
高級下拉列表：簡易下拉列表  |  依賴下拉列表  |  多選下拉列表...
列管理器：添加特定數量的列  |  移動列  |  切換隱藏列的可見狀態  |  比較列以選擇相同和不同的單元格 ...
特色功能：網格聚焦  |  設計檢視  |  增強編輯欄  |  工作簿與工作表管理器 | 資源庫（自動文本）  |  日期提取器  |  合併資料  |  加密/解密儲存格  |  按清單發送電子郵件  |  超級篩選  |  特殊篩選（篩選粗體/斜體/刪除線...) ...
頂級 15 種工具集:  12 個文字工具（添加文本、刪除特定字符 ...)  |  50+ 圖表 類型（甘特圖 ...)  |  40+ 實用 公式（基於生日計算年齡 ...)  |  19 個插入工具（插入QR碼、從路徑插入圖片 ...)  |  12 個轉換工具（金額轉大寫、匯率轉換 ...)  |  7 個合併與分割工具（高級合併行、分割Excel單元格 ...)  |  ... 還有更多

Kutools for Excel 擁有超過 300 種功能，確保您需要的功能只需點擊一下即可實現...

Office Tab - 啟用 Microsoft Office（包括 Excel）中的分頁閱讀和編輯功能

  • 一秒鐘內在數十個打開的文檔之間切換！
  • 每天為您減少數百次鼠標點擊，告別滑鼠手。
  • 當查看和編輯多個文檔時，您的工作效率提高 50%。
  • 為 Office（包括 Excel）帶來高效的分頁功能，就像 Chrome、Edge 和 Firefox 一樣。