在 Excel 中從儲存格提取除第一個或最後一個以外的所有單字

在本教學中，您將學會如何運用公式，從 Excel 儲存格中提取除第一個或最後一個以外的所有單字。

在 Excel 中從儲存格提取除第一個以外的所有單字
在 Excel 中從儲存格提取除最後一個以外的所有單字

在 Excel 中從儲存格提取除第一個以外的所有單字

如下方截圖所示，若要從 B 欄每個儲存格中提取第一個單字以外的所有內容，可結合使用 RIGHT、LEN 與 FIND 函數來達成。請依下列步驟操作。

通用公式

=RIGHT(text_string,LEN(text_string)-FIND(" ",text_string,1))

引數

如何使用這個公式？

1. 選取一個空白儲存格來輸出提取的單字；本例中，我選擇了 D3 儲存格。

2. 在儲存格中輸入下方公式，然後按下 Enter 鍵，接著選取該公式儲存格並向下拖曳，即可套用至其他儲存格。

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

現已從指定儲存格中提取出除第一個單字以外的所有單字。

注意：在上述公式中，B3 是包含您要提取（除第一個字以外）其餘文字的儲存格，請依需求調整。

這個公式是如何運作的？

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

1. LEN(B3)：LEN 函數計算「Excel handy addin」的總字元數，並傳回結果 17；

2. FIND(" ",B3,1)：由於單字以空格分隔，FIND 函數會找出「Excel handy addin」中第一個空格的位置，並傳回結果 6；

3. RIGHT(B3,17-6)：RIGHT 函數從文字字串「Excel handy addin」右側提取 11 個字元（17－6＝11），結果為「handy addin」。

在 Excel 中從儲存格提取除最後一個以外的所有單字

在本節中，我們將結合運用 LEFT、FIND、SUBSTITUTE 與 LEN 函數，從 Excel 的指定儲存格中提取除最後一個單字以外的所有文字。

通用公式

=LEFT(text_string,FIND("[",SUBSTITUTE(text_string," ","[",LEN(text_string)-LEN(SUBSTITUTE(text_string," ",""))))-1)

引數

如何使用這個公式？

1. 選取一個空白儲存格（本例為 D3），用來輸出提取的單字。

2. 在儲存格中輸入下方公式，然後按下 Enter 鍵，再向下拖曳該儲存格以套用至其他儲存格。

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

現已從指定儲存格中提取出除最後一個單字外的所有文字。

注意：在上述公式中，B3 是包含您要提取（除最後一個字以外）之文字的儲存格，請依需求調整。

這個公式是如何運作的？

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

1. SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ","")))

• LEN(B3)：LEN 函數計算文字「Excel handy addin」的總長度，並傳回結果 17；
• LEN(SUBSTITUTE(B3," ",""))：SUBSTITUTE 函數移除「Excel handy addin」中的所有空格，傳回「Excelhandyaddin」，接著 LEN 函數計算「Excelhandyaddin」的總長度，最終結果為 15；
• SUBSTITUTE(B3," ","[",17-15))SUBSTITUTE 函數將「Excel handy addin」中的第二個空格替換為字元「【」，並傳回結果「Excel handy[addin」。

2. FIND("[","Excel handy[addin")

• FIND 函數在文字字串「Excel handy[addin」中找出字元「[」的位置。在此範例中，字元「[」位於該字串的第 12 個位置，因此傳回結果 12.

3. =LEFT(B3,12-1)

• LEFT 函數從文字字串「Excel handy addin」的左側提取 11 個字元（12－1＝11），結果為「Excel handy」。

相關函數

相關公式