從 Excel 的儲存格中提取除第一個或最後一個以外的所有單詞

在本教程中，我們將學習如何使用公式從 Excel 的儲存格中提取除第一個或最後一個單詞之外的所有單詞。

從 Excel 的儲存格中提取除第一個以外的所有單詞
從 Excel 的儲存格中提取除最後一個以外的所有單詞

從 Excel 的儲存格中提取除第一個以外的所有單詞

如下方的屏幕截圖所示，您希望從 B 列每個儲存格中提取除第一個單詞外的所有單詞，可以使用 RIGHT、LEN 和 FIND 函數的組合來實現。請按照以下步驟操作。

通用公式

=RIGHT(text_string,LEN(text_string)-FIND(" ",text_string,1))

參數

如何使用此公式？

1. 選擇一個空白儲存格以輸出提取的單詞。在此情況下，我選擇了 D3 儲存格。

2. 將以下公式輸入其中並按下 Enter 鍵。然後選擇並將公式儲存格向下拖動以應用於其他儲存格。

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

現在，特定儲存格中的所有單詞都已提取出來，除了第一個單詞。

注意：在上述公式中，B3 是包含您要提取單詞（除第一個單詞外）的儲存格。請根據需要進行更改。

這個公式是如何工作的？

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

1. LEN(B3): LEN 函數計算 Excel handy addin 的總長度，並返回結果為 17；

2. FIND(" ",B3,1): 因為單詞之間由空格分隔，這裡 FIND 函數定位到 Excel handy addin 中第一個空格的位置，並返回結果為 6；

3. RIGHT(B3,17-6): RIGHT 函數從文本字符串 "Excel handy addin" 的右側提取 11 個字符（17-6=11）。結果是 "handy addin"。

從 Excel 的儲存格中提取除最後一個以外的所有單詞

在本節中，我們將使用 LEFT、FIND、SUBSTITUTE 和 LEN 函數的組合來從 Excel 的特定儲存格中提取除最後一個單詞外的所有單詞。

通用公式

=LEFT(text_string,FIND("[",SUBSTITUTE(text_string," ","[",LEN(text_string)-LEN(SUBSTITUTE(text_string," ",""))))-1)

參數

如何使用此公式？

1. 選擇一個空白儲存格（例如本例中的 D3）以輸出提取的單詞。

2. 將以下公式輸入其中並按下 Enter 鍵。然後將公式儲存格向下拖動以應用於其他儲存格。

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

現在，特定儲存格中的所有單詞都已提取出來，除了最後一個單詞。

注意：在上述公式中，B3 是包含您要提取單詞（除最後一個單詞外）的儲存格。請根據需要進行更改。

這個公式是如何工作的？

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

1. SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ","")))

• LEN(B3): LEN 函數計算文本 "Excel handy addin" 的總長度，並返回結果為 17；
• LEN(SUBSTITUTE(B3," ","")): SUBSTITUTE 函數移除 "Excel handy addin" 中的所有空格，並返回 "Excelhandyaddin"，然後 LEN 函數計算文本 "Excelhandyaddin" 的總長度。最終結果為 15；
• SUBSTITUTE(B3," ","[",17-15)): SUBSTITUTE(B3," ","[",2)) SUBSTITUTE 函數將 "Excel handy addin" 中的第二個空格替換為字符 "["，並返回結果為 "Excel handy[addin"。

2. FIND("[","Excel handy[addin")

• FIND 函數定位到文本字符串 "Excel handy[addin" 中字符 "[" 的位置。這裡字符 "[" 在文本字符串的第 12 位，因此返回結果為 12；

3. =LEFT(B3,12-1)

• LEFT 函數從文本字符串 "Excel handy addin" 的左側提取 11 個字符（12-1=11）。結果是 "Excel handy"。

相關函數

相關公式