如何在Excel中列出所有資料夾和子資料夾？

在進行目錄或檔案管理任務時，您可能需要快速獲取特定目錄內所有資料夾和子資料夾的完整清單，並將該資訊直接檢視在Excel中。然而，Excel並未提供內建功能或簡單的精靈來自動從指定的資料夾路徑檢索所有資料夾或子資料夾名稱。本文介紹VBA程式碼 —— 讓您可以將任何選定目錄中的所有資料夾和子資料夾直接列印到工作表中。這能減少人為錯誤的風險並消除繁瑣的工作，幫助您快速追蹤和管理您的資料組織。

使用VBA程式碼列出所有資料夾和子資料夾

使用VBA程式碼列出所有資料夾和子資料夾

如果您想從指定目錄中提取並顯示所有資料夾和子資料夾名稱到Excel中，利用VBA（Visual Basic for Applications）是一種有效的解決方案。此方法提供了靈活性和控制力，讓您不僅可以獲取資料夾名稱，還可以獲得額外的資訊，例如資料夾路徑、建立日期和最後修改日期。這種方法特別適合熟悉使用Excel開發者功能的使用者，以及那些處理動態或經常變化的檔案系統的人。

1. 按下 ALT + F11 開啟「Microsoft Visual Basic for Applications」編輯器。此工具可讓您在工作簿中新增和編輯宏。

2. 在VBA編輯器中，點擊 插入 > 模組。這將創建一個新的模組窗口。將以下程式碼複製並貼上到模組中：

VBA程式碼：列出所有資料夾和子資料夾名稱

Sub FolderNames()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim xPath As String
Dim xWs As Worksheet
Dim fso As Object, j As Long, folder1 As Object
With Application.FileDialog(msoFileDialogFolderPicker)
    .Title = "Choose the folder"
    .Show
End With
On Error Resume Next
xPath = Application.FileDialog(msoFileDialogFolderPicker).SelectedItems(1) & "\"
Application.Workbooks.Add
Set xWs = Application.ActiveSheet
xWs.Cells(1, 1).Value = xPath
xWs.Cells(2, 1).Resize(1, 5).Value = Array("Path", "Dir", "Name", "Date Created", "Date Last Modified")
Set fso = CreateObject("Scripting.FileSystemObject")
Set folder1 = fso.getFolder(xPath)
getSubFolder folder1
xWs.Cells(2, 1).Resize(1, 5).Interior.Color = 65535
xWs.Cells(2, 1).Resize(1, 5).EntireColumn.AutoFit
Application.ScreenUpdating = True
End Sub
Sub getSubFolder(ByRef prntfld As Object)
Dim SubFolder As Object
Dim subfld As Object
Dim xRow As Long
For Each SubFolder In prntfld.SubFolders
    xRow = Range("A1").End(xlDown).Row + 1
    Cells(xRow, 1).Resize(1, 5).Value = Array(SubFolder.Path, Left(SubFolder.Path, InStrRev(SubFolder.Path, "\")), SubFolder.Name, SubFolder.DateCreated, SubFolder.DateLastModified)
Next SubFolder
For Each subfld In prntfld.SubFolders
    getSubFolder subfld
Next subfld
End Sub

3. 插入程式碼後，按下 F5 或點擊VBA編輯器中的 執行 按鈕來執行宏。隨後會出現一個 選擇資料夾 對話框，提示您選擇要掃描資料夾和子資料夾的目標目錄。

4. 選擇所需的目錄並點擊 確定。宏將處理該目錄並生成一個新工作簿，列出所有資料夾和子資料夾及其完整路徑、直接父目錄、名稱、建立日期和最後修改日期，如下所示：

這個VBA解決方案靈活，不需要額外的外掛或外部軟體，並自動創建一個輸出工作簿以便於使用。然而，它最適合熟悉基本宏操作的用戶，並且可能需要針對特定自訂進行額外調整。

相關文章：

如何在Excel中將目錄中的檔案列表到工作表？