如何將 Word 文件中的每一頁分別儲存為獨立的 PDF 檔案？

作者Siluvia修改日期2025-04-11

在 Microsoft Word 中，您可以手動使用內建的「另存新檔」功能，並在選項對話框中指定頁碼，將每一頁儲存為獨立的 PDF。然而，若處理的是包含數百頁的大型文件，手動操作將耗費大量時間。本文介紹一種能快速將所有頁面儲存為個別 PDF 檔案的方法。

使用 VBA 程式碼批次將每一頁儲存為獨立的 Pdf 文件

您可以使用下方的 VBA 程式碼，將 Word 文件中的每一頁自動儲存為獨立的 PDF 檔案。操作步驟如下：

開啟您要處理的 Word 文件，按下 Alt + F11 即可開啟 Microsoft Visual Basic for Applications 視窗。

在 Visual Basic 視窗中，點選「插入」>「模組」，然後將下列 VBA 程式碼貼到模組視窗中：

Sub SaveAsSeparatePDFs()
'Updated by Extendoffice 20180906
    Dim I As Long
    Dim xStr As String
    Dim xPathStr As Variant
    Dim xDictoryStr As String
    Dim xFileDlg As FileDialog
    Dim xStartPage, xEndPage As Long
    Dim xStartPageStr, xEndPageStr As String
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    If xFileDlg.Show <> -1 Then
        MsgBox "Please chose a valid directory", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xPathStr = xFileDlg.SelectedItems(1)
    xStartPageStr = InputBox("Begin saving PDFs starting with page __? " & vbNewLine & "(ex: 1)", "Kutools for Word")
    xEndPageStr = InputBox("Save PDFs until page __?" & vbNewLine & "(ex: 7)", "Kutools for Word")
    If Not (IsNumeric(xStartPageStr) And IsNumeric(xEndPageStr)) Then
        MsgBox "The enterng start page and end page should be number format", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xStartPage = CInt(xStartPageStr)
    xEndPage = CInt(xEndPageStr)
    If xStartPage > xEndPage Then
        MsgBox "The start page number can't be larger than end page", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    If xEndPage > ActiveDocument.BuiltInDocumentProperties(wdPropertyPages) Then
        xEndPage = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
    End If
    For I = xStartPage To xEndPage
        ActiveDocument.ExportAsFixedFormat xPathStr & "\Page_" & I & ".pdf", _
        wdExportFormatPDF, False, wdExportOptimizeForPrint, wdExportFromTo, I, I, wdExportDocumentWithMarkup, _
        False, False, wdExportCreateHeadingBookmarks, True, False, False
    Next
End Sub

按下 F5 以執行程式碼。
在彈出的瀏覽視窗中，選擇用於儲存 PDF 檔案的資料夾，然後點擊「確定」。
在第一個「Kutools for Word」對話框中，輸入起始頁碼，然後點擊「確定」。
在第二個「Kutools for Word」對話框中，輸入結束頁碼，然後點擊「確定」。
注意：例如，若要儲存連續的第 4、5、6 頁，只需在兩個對話框中分別輸入「4」和「6」即可。