Outlook：身为主办人，如何在行事历中保留已取消的会议？

在 Outlook 中，當您身為會議組織者取消會議時，該會議會自動從行事曆中移除。但在某些情況下，您可能希望將已取消的會議保留在行事曆中，以便進行標記或記錄。可惜的是，Outlook 本身並未內建支援此需求的功能。本教學提供兩段 VBA 程式碼，讓您在取消會議的同時，將其保留為一般的預約項目。

用於將已取消會議複製為預約項目的 VBA 程式碼

---

用於將已取消會議複製為預約項目的 VBA 程式碼

以下是兩段程式碼，可在取消會議的同時，將其複製並貼上為預約項目。

注意：啟用程式碼前，請確認已勾選以下兩個選項：

啟動 Outlook，點擊檔案＞選項。在 Outlook 選項視窗中，點擊信任中心索引標籤，再點擊信任中心設定。接著在信任中心視窗中，點擊巨集設定索引標籤，勾選啟用所有巨集（不建議；可能執行危險程式碼）與將巨集安全性設定套用至已安裝的增益集選項，然後點擊確定＞ 確定 以關閉視窗。重新啟動 Outlook。

1. 切換至行事曆檢視，選取您要取消的會議，按下 Alt＋F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 點擊插入＞模組，即可新增一個空白模組，接著將下方程式碼複製並貼上至其中！

程式碼：將會議複製為預約項目並予以取消

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. 點擊執行按鈕，或按下 F5 鍵，即可取消所選會議，並自動建立一個名為「已取消」、主題相同的約會。

若您希望先將會議複製並貼上為另一個行事曆中的預約項目，再取消原會議，請使用下方程式碼：

程式碼：將會議複製為另一個行事曆中的預約項目並予以取消

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

點擊執行按鈕，或按下 F5 鍵，系統將立即彈出「選取資料夾」對話方塊，讓您快速選擇要貼上預約項目的行事曆資料夾，再點擊確定即可！

現在，該會議已取消，並已複製為您所選行事曆資料夾中的預約項目。