如何將生日從 Excel 匯入到 Outlook 日曆？

Author: Xiaoyang Last Modified: 2025-08-06

如果您在工作表中有一長串的生日資訊，現在您想將這些生日作為事件匯入到您的 Outlook 日曆中。該如何使用一些快速的方法來處理這個任務呢？

使用 VBA 程式碼將生日從 Excel 匯入到 Outlook 日曆

通常，沒有直接的方法可以將生日匯入到 Outlook 日曆中。因此，我將創建一個 VBA 程式碼來解決這個問題，請按照以下步驟操作：

1. 打開包含要匯入到 Outlook 的生日的工作表，然後按住 ALT + F11 鍵以打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊插入 > 模組，然後將以下程式碼粘貼到模組視窗中。

VBA 程式碼：將生日匯入到 Outlook 日曆

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. 仍在 Microsoft Visual Basic for Applications 視窗中，點擊工具 > 參考資料。在彈出的「參考資料 – VBAProject」對話框中，勾選 「可用的參考資料」列表框中的 Microsoft Outlook 16.0 Object Library 選項，參見截圖：