Outlook：如何在未收到回覆時自動重新寄送電子郵件

當您傳送電子郵件給同事、合作夥伴或其他人，並急需對方回覆時，可啟用自動重新寄送功能；若在指定時間內未收到回覆，系統將自動再次寄送該郵件。

使用提醒與 VBA 設定「未收到回覆時自動重新寄送」

---

使用提醒與 VBA 設定「未收到回覆時自動重新寄送」

步驟 1：設定提醒，在指定時間進行通知

1. 針對您希望在未收到回覆時重新寄送的電子郵件（位於「已傳送郵件」資料夾中），請按一下滑鼠右鍵，並在彈出的快捷選單中選擇「後續追蹤」>「新增提醒」。

2. 在彈出的「自訂」對話方塊中，請先勾選「提醒」核取方塊，接著於下方下拉式方塊中選擇您希望對方回覆的截止日期與時間，或直接在欄位中輸入日期與時間。設定完成後，點選「確定」。

步驟 2：插入 VBA 程式碼，於指定時間內未收到回覆時自動重新寄送郵件

3. 按下「Alt」+「F11」鍵，即可開啟「Microsoft Visual Basic for Applications」視窗。

4. 在「專案 – Project 1」窗格中雙擊「ThisOutlookSession」，建立空白指令碼，並將下方的 VBA 程式碼複製貼上至該空白指令碼中。

VBA：未收到回覆時重新寄送電子郵件

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. 儲存程式碼後，返回主介面，點選「檔案」＞「選項」，在「Outlook 選項」視窗中，點選左側窗格的「信任中心」，再點選「信任中心設定」以開啟「信任中心」視窗；接著點選「巨集設定」，並確保右側已選取「啟用所有巨集（不建議；可能執行危險程式碼）」選項。設定完成後，依序點選「確定」＞「確定」。

6. 現在，當設定提醒的已傳送郵件在指定時間到達時仍未收到回覆，系統會彈出對話方塊，詢問您是否要重新寄送郵件以發出通知。

7. 點選「是」後，系統將彈出郵件視窗並附上先前的郵件內容，您可重新編輯內文，再點選「傳送」即可重新寄送郵件。

8. 點選「否」，即可刪除該提醒。

注意：若郵件在指定時間前已收到回覆，VBA 將自動取消該提醒。