如何在不打開郵件的情況下保存Outlook中的附件？

Author: Siluvia Last Modified: 2025-08-06

您可能經常需要將收到的郵件中的附件保存到電腦磁盤中。從一封郵件中保存一個或所有附件很容易，但如何一次性從多封郵件中保存附件呢？通常情況下，您需要反覆打開郵件並保存附件。有沒有什麼技巧可以避免這種重複操作呢？本教程中的方法可以幫助您。

使用VBA代碼保存一個或多個郵件中的附件而無需打開
使用一款出色的工具保存一個或多個郵件中的附件而無需打開

使用VBA代碼保存一個或多個郵件中的附件而無需打開

以下VBA代碼可以幫助您同時從一封或多封郵件中保存附件，而無需在Outlook中打開郵件。請按照以下步驟操作：

1. 選擇要保存附件的一封或多封郵件，按下 Alt + F11 鍵以打開 Microsoft Visual Basic for Applications 窗口。

2. 展開 Microsoft Outlook Objects 文件夾，雙擊 ThisOutlookSession 打開代碼窗口，然後將以下VBA代碼複製到其中。

VBA代碼：在不打開郵件的情況下保存附件

Public Sub SaveAttachmentsWithoutOpening()
'Updated by Extendoffice 20191008
Dim xMailItem As Outlook.MailItem
Dim xAttachments As Outlook.Attachments
Dim xAttachment As Outlook.Attachment
Dim i As Long
Dim xCount As Long
Dim xFileName As String
Dim xSavePath As String
Dim xOriginalFiles As String
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, strStartingFolder)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xSavePath = xFolderItem.Path & "\"
Else
    xFileName = ""
    Exit Sub
End If
For Each xMailItem In Outlook.ActiveExplorer.Selection
    Set xAttachments = xMailItem.Attachments
    xCount = xAttachments.Count
    xOriginalFiles = ""
    If xCount > 0 Then
        For i = xCount To 1 Step -1
            Set xAttachment = xAttachments.Item(i)
            If IsEmbeddedAttachment(xAttachment) = False Then
                xFileName = xSavePath & xAttachment.FileName
                xAttachment.SaveAsFile xFileName
                xAttachment.Delete
                If xMailItem.BodyFormat <> olFormatHTML Then
                    xOriginalFiles = xOriginalFiles & vbCrLf & "file://" & xFileName
                Else
                    xOriginalFiles = xOriginalFiles & "<br>" & "<a href='file://" & xFileName & "'>" & xFileName & "</a>"
                End If
            End If
        Next i
        If xMailItem.BodyFormat <> olFormatHTML Then
            xMailItem.Body = "The file(s) were saved to " & xOriginalFiles & vbCrLf & vbCrLf & xMailItem.Body
        Else
            xMailItem.HTMLBody = "<p>" & "The file(s) were saved to " & xOriginalFiles & "</p>" & xMailItem.HTMLBody
        End If
        xMailItem.Save
    End If
Next
Set xAttachments = Nothing
Set xMailItem = Nothing
End Sub

Function IsEmbeddedAttachment(Attach As Attachment)
Dim xItem As MailItem
Dim xCid As String
Dim xID As String
Dim xHtml As String
On Error Resume Next
IsEmbeddedAttachment = False
Set xItem = Attach.Parent
If xItem.BodyFormat <> olFormatHTML Then Exit Function
xCid = ""
xCid = Attach.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001F")
If xCid <> "" Then
    xHtml = xItem.HTMLBody
    xID = "cid:" & xCid
    If InStr(xHtml, xID) > 0 Then
        IsEmbeddedAttachment = True
    End If
End If
End Function

4. 按下 F5 鍵運行代碼。隨後會彈出一個 BrowseForFolder 窗口，請選擇一個文件夾來保存附件，然後點擊確定按鈕。

然後，所選郵件中的所有附件都會立即保存到所選文件夾中。

注意：所有附件都將從郵件中拆離，並在郵件正文中保留相應的保存路徑鏈接。

使用一款出色的工具保存一個或多個郵件中的附件而無需打開

如果您是VBA的新手，本節的方法將是您的不錯選擇。

在此推薦給您 Kutools for Outlook 的 Save All attachments 工具。如果您只想保存附件而不從所選郵件中拆離，Save All attachments 功能可以輕鬆幫您完成。請按照以下步驟操作。
在應用 Kutools for Outlook 之前，請先下載並安裝它 。

使用 Kutools for Outlook 解鎖極致郵件效率！永久免費獲取 70 項強大功能。立即下載免費版本！

1. 選擇包含要保存附件的郵件，點擊 Kutools Plus > 附件工具 > 儲存附件。

2. 在儲存設定對話框中，您需要：