如何在 Outlook 中自動將已傳送的會議邀請移至特定資料夾？

一般情況下，傳送電子郵件或會議邀請後，兩者都會存入「已傳送郵件」資料夾，導致該資料夾變得雜亂且難以管理。本文將介紹一種方法，讓會議邀請在送出後自動移至其他指定資料夾。

使用 VBA 程式碼自動將已傳送的會議移至特定資料夾

---

使用 VBA 程式碼自動將已傳送的會議移至特定資料夾

若要自動將所有已傳送的會議邀請移至其他資料夾，可使用下列程式碼，請依下列步驟操作：

1. 按住 ALT + F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 在 Microsoft Visual Basic for Applications 視窗中，於 Project 1(VbaProject.OTM) 窗格內雙擊 ThisOutlookSession 以開啟模組，然後將下列程式碼複製並貼上至空白模組中。

VBA 程式碼：自動將已傳送的會議移至特定資料夾

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

3. 接著，保存並關閉程式碼視窗。此後，每當傳送會議郵件時，系統將自動將其移至已傳送郵件資料夾下的新建資料夾「Meetings」，請參閱截圖：