如何在 Outlook 中回覆或轉寄郵件時保留原有的分類？

一般情況下，當您回覆或轉寄一封已分類的郵件時，該分類會自動從寄件郵件中移除。若您希望在回覆或轉寄時保留原有分類，本文將為您介紹一種解決方法。

使用 VBA 程式碼在回覆或轉寄郵件時保留分類

---

使用 VBA 程式碼在回覆或轉寄郵件時保留分類

1. 按住 ALT + F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 在 Microsoft Visual Basic for Applications 視窗中，雙擊 Project 1 (VbaProject.OTM) 窗格中的 ThisOutlookSession 以開啟模組，然後將下列程式碼複製並貼上至空白模組中。

VBA 程式碼：回覆或轉寄郵件時保留分類：

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. 接著保存並關閉此程式碼視窗，然後關閉並重新啟動 Outlook。現在，當您在回覆或轉寄帶有分類的郵件時，該分類將保留在已傳送郵件的寄件郵件中，請參見截圖：