如何在 Outlook 的「已傳送郵件」資料夾中正常回覆郵件？

當您在「已傳送郵件」資料夾中點擊「回覆」，想向先前郵件的收件人再次發送額外訊息時，Outlook 通常會將您自己的信箱地址自動填入「收件者」欄位（如下方截圖所示）。每次都要手動更改收件者，是否讓您感到困擾？如何設定 Outlook，使其自動使用原始收件人的地址，而非您的信箱地址？

在 Outlook 的已傳送郵件資料夾中使用「全部回覆」功能正常回覆

在 Outlook 的已傳送郵件資料夾中使用 VBA 程式碼正常回覆

---

在 Outlook 的已傳送郵件資料夾中使用「全部回覆」功能正常回覆

在 Outlook 中，全部回覆功能可協助您解決此問題，請依照下列步驟操作：

當您需要回覆已傳送的郵件，並再次寄送以保留原始收件人地址時，請點擊全部回覆按鈕，此時原始收件人地址會出現在收件者欄位中，如下方截圖所示：

---

在 Outlook 的已傳送郵件資料夾中使用 VBA 程式碼正常回覆

有時，當您在回覆已傳送的郵件時，可能會忘記使用全部回覆功能。以下 VBA 程式碼可協助您在「已傳送郵件」資料夾中點選「回覆」時，自動正常回覆！請依照下列步驟操作：

1. 按住 ALT + F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 在 Microsoft Visual Basic for Applications 視窗中，於 Project 1 (VbaProject.OTM) 窗格中雙擊 ThisOutlookSession 以開啟模組，然後將下列程式碼複製並貼上至空白模組中。

VBA 程式碼：在 Outlook 的已傳送郵件資料夾中正常回覆：

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. 接著儲存程式碼並重新啟動 Outlook，以使設定生效。現在，當您在已傳送郵件資料夾中點擊「回覆」來重新寄送郵件時，原始收件人地址就會如您所需地顯示在「收件者」欄位中。回覆