如何在 Outlook 中依分類列印郵件？

假設您的 Outlook 工作中包含多種顏色類別，現在您希望將不同分類的工作清單分別列印在不同頁面上。該如何在 Outlook 中完成這項任務呢？

手動逐一依分類將工作列印至不同頁面

使用 VBA 程式碼將工作依分類列印至不同頁面

---

手動逐一依分類將工作列印至不同頁面

在 Outlook 中，您可以手動逐一將不同分類的工作分別列印至不同頁面，請依照下列步驟操作：

1. 啟動 Outlook，進入「工作」窗格，選取您要列印的工作資料夾，然後按下 Ctrl + E 以啟用搜尋方塊；接著在搜尋索引標籤下，按一下分類圖示，並選擇一個您需要列印的色彩類別，如下圖所示：

2. 此時，所有符合指定色彩類別的工作會立即列出，如下圖所示：

3. 接著，依序點選檔案＞ 列印，即可列印此工作清單，如下圖所示：

4. 重複上述步驟，即可手動逐一列印其他顏色類別的工作清單。

---

使用 VBA 程式碼將工作依分類列印至不同頁面

以下提供一段 VBA 程式碼，可協助您一次性將不同分類的工作分別列印至不同頁面，請依照下列步驟操作：

1. 進入工作窗格，並選取您要列印的工作資料夾。

2. 接著，按下 ALT + F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

3. 然後點選插入＞ 模組，並將下方程式碼複製貼上至開啟的空白模組中：

VBA 程式碼：依分類將工作列印至不同頁面：

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. 接著，在工具＞ 參考設定 中（位於 ）Microsoft Visual Basic for Applications 視窗），於彈出的 參考設定 - Project 1 對話方塊中，從 Microsoft Excel 物件程式庫與 Microsoft Scripting Runtime 選項中勾選可用參考項目清單方塊中的項目，如下圖所示：

5. 按一下確定按鈕，再按下 F5 鍵執行此程式碼。執行完畢後，不同分類的工作清單將自動列印至不同頁面。