Skip to main content

如何在 Outlook 的「選取名稱」清單中隱藏傳真號碼?

Author: Sun Last Modified: 2025-05-12

在 Outlook 中,您可能已經發現,在「選取名稱」清單或通訊簿中,電子郵件地址欄不僅包含電子郵件地址,還包含可能讓您感到困擾的傳真條目。在本文中,我將介紹一些隱藏傳真號碼的方法給您。
doc hide fax number 1

使用 VBA 隱藏「選取名稱」清單中的傳真號碼


使用 VBA 隱藏「選取名稱」清單中的傳真號碼

如果您想隱藏「選取名稱」清單中已有的傳真號碼,請按照以下步驟操作:

1. 按 Alt + F11 鍵以啟用 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組 以插入一個新的空白模組,然後複製並將以下程式碼粘貼到腳本中。

VBA:隱藏「選取名稱」中的現有傳真號碼

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. 按 F5 鍵執行程式碼,現在傳真號碼已被隱藏。
doc hide fax number 2

如果您想在新聯絡人中隱藏傳真號碼,請按照以下步驟操作:

1. 按 Alt + F11 鍵以啟用 Microsoft Visual Basic for Applications 視窗。

2. 在專案-1 窗格中雙擊 ThisOutlookSession,然後複製並將以下程式碼粘貼到腳本中。

VBA:隱藏新添加聯絡人中的傳真號碼

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub
doc hide fax number 3

3. 儲存程式碼並重新啟動 Outlook 以使程式碼生效。

從現在開始,所有新建聯絡人的傳真號碼都將在「選取名稱:聯絡人」視窗中被隱藏。

doc hide fax number 4
doc arrow down
doc hide fax number 5

Outlook中的AI郵件助理:更聰明的回覆,更清晰的溝通(一鍵奇蹟!) 免費

使用Kutools for Outlook的AI郵件助理簡化您的日常Outlook任務。這個強大的工具會從您過去的郵件中學習,提供智能且準確的答覆,優化您的郵件內容,並幫助您輕鬆起草和潤色郵件。
doc ai email handle

此功能支援:

  • 智能回覆:根據您過去的對話獲得量身定制、精確且隨時可用的回覆。
  • 增強內容:自動優化您的郵件文字以提高清晰度和影響力。
  • 輕鬆撰寫:只需提供關鍵字,讓AI處理其餘部分,並有多種寫作風格可供選擇。
  • 智能擴展:通過上下文感知建議來拓展您的思路。
  • 摘要生成:即時獲取長郵件的簡潔概述。
  • 全球觸及:輕鬆將您的郵件翻譯成任何語言。

此功能支援:

  • 智能郵件回覆
  • 優化的內容
  • 基於關鍵字的草稿
  • 智能內容擴展
  • 郵件摘要生成
  • 多語言翻譯

最重要的是,此功能永遠完全免費不要再等待了——立即下載AI郵件助理並享受吧