如何在 Outlook 中自動將超過指定天數的未讀郵件標記為已讀？

如果您的收件匣資料夾中有大量未讀郵件，通常可使用「全部標記為已讀」功能，手動將所有未讀郵件一次標記為已讀。但您是否曾想過，在 Outlook 中能否無需每次手動操作，就自動將超過指定天數的未讀郵件標記為已讀？

使用 VBA 程式碼自動將超過指定天數的未讀郵件標記為已讀

---

使用 VBA 程式碼自動將超過指定天數的未讀郵件標記為已讀

若要自動將超過指定天數的所有未讀郵件標記為已讀，下列 VBA 程式碼可協助您達成：

1. 按住 ALT + F11 鍵，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 在 Microsoft Visual Basic for Applications 視窗中，於 Project 1(VbaProject.OTM) 窗格內雙擊 ThisOutlookSession 以開啟模組，然後將下方程式碼複製並貼上至空白模組中。

VBA 程式碼：自動將超過指定天數的未讀郵件標記為已讀：

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

注意：在上述程式碼中，您可以根據需求調整此段腳本中的天數：If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15Then。

3. 接著保存並關閉此程式碼視窗，從此以後，每當您啟動 Outlook 時，所有超過預設天數的未讀郵件將立即自動標記為已讀。

注意：此程式碼僅適用於預設資料帳戶。