如何在 Outlook 中將電子郵件訊息儲存為圖片格式（jpg/tiff）？

Author: Siluvia Last Modified: 2025-08-06

您是否曾經嘗試過在Outlook中將電子郵件訊息保存為jpg或tiff圖片？本文將向您展示解決此問題的方法。

使用VBA代碼將電子郵件訊息保存為圖片格式

使用VBA代碼將電子郵件訊息保存為圖片格式

請按照以下步驟在Outlook中將電子郵件訊息保存為圖片格式。

1. 選擇要保存為圖片的電子郵件，然後同時按下 Alt + F11 鍵以打開 Microsoft Visual Basic for Applications 窗口。

2. 在 Microsoft Visual Basic for Applications 窗口中，請點擊插入 > UserForm。參見截圖：

steps on saving email message as picture format (jpg/tiff) in outlook

3. 創建如下截圖所示的用戶窗體。

4. 選擇 jpg 選項按鈕，並在左側屬性窗格中將其名稱更改為 opbJPG。

5. 重複上述步驟 4，將其他選項按鈕重命名為 opbTIFF。並將“確定”命令按鈕和“取消”命令按鈕分別重命名為 cdbOk 和 cdbCancel 。

注意：如果屬性窗格未顯示在 Microsoft Visual Basic for Applications 窗口中，請按 F4 鍵以顯示該窗格。

6. 雙擊用戶窗體上的任何空白區域以打開代碼窗口。用以下VBA腳本替換所有代碼。然後關閉代碼窗口。

VBA代碼1：將電子郵件訊息保存為圖片

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. 選擇 UserForm1 並在屬性窗格中將其名稱更改為 FrmPicType ，如下截圖所示。

8. 點擊插入 > 模塊，然後將以下VBA代碼複製到模塊窗口中。

VBA代碼2：將電子郵件訊息保存為圖片

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. 點擊工具 > 引用，勾選 Microsoft PowerPoint Object Library 框，然後點擊確定按鈕。參見截圖：