如何在 Outlook 中透過資料夾名稱快速找到對應的完整路徑？

請依照下列步驟，在 Outlook 中使用 VBA 依資料夾名稱搜尋資料夾。

1. 同時按下「Alt」+「F11」鍵，即可開啟「Microsoft Visual Basic for Applications」視窗。

2. 點選「插入」>「模組」，並將下方的 VBA 程式碼貼上至新開啟的模組視窗中。

VBA：在 Outlook 中依資料夾名稱搜尋並打開文件夾

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. 按下「F5」鍵或點選「執行」按鈕，即可執行此 VBA。

4. 在跳出的「搜尋資料夾」對話方塊中，請輸入您要搜尋的指定資料夾名稱，然後點選「確定」按鈕。

注意：此 VBA 支援萬用字元星號（*）。例如，輸入 tes* 即可快速找出所有名稱以 tes 開頭的資料夾！

5. 此時將彈出一個對話方塊，顯示所找到資料夾的完整路徑。若需開啟該資料夾，請點選「是」按鈕。

現在，所找到的資料夾已在導航中開啟，如下圖所示：

注意：若有多個資料夾使用相同的指定名稱，此 VBA 僅會找出並開啟其中一個。

若您已安裝「Kutools for Outlook」，即可運用其「前往」功能，快速搜尋所有符合指定資料夾名稱的資料夾，並一鍵輕鬆開啟任一搜尋結果。

1. 點選「KUTOOLS PLUS」>「前往」，即可啟用此功能。

2. 在「前往」對話方塊的「搜尋」欄位中輸入指定的資料夾名稱，從搜尋結果中選取目標資料夾，然後點選「確定」按鈕。

現在，系統會立即找到並開啟具有該特定名稱的指定資料夾。