如何在 Outlook 中匯出並列印所有資料夾及其子資料夾的清單？

一般來說，您可以按下「Ctrl」+「6」鍵，在 Outlook 導航窗格中快速查看所有資料夾的清單。不過，Outlook 並未提供直接列印該資料夾清單的功能。本文將為您介紹兩個實用的 VBA 腳本，協助您輕鬆匯出並列印 Outlook 中所有資料夾及其子資料夾的完整清單。

• 將所有 Outlook 資料夾及其子資料夾的清單匯出並列印至新建郵件
• 將所有 Outlook 資料夾及其子資料夾的清單匯出並列印至記事本

---

將所有 Outlook 資料夾及其子資料夾的清單匯出並列印至新建郵件

此方法介紹一個 VBA 腳本，能將指定電子郵件帳戶中的所有資料夾與子資料夾清單，自動匯出至 Outlook 的新郵件中，讓您輕鬆列印完整的資料夾結構清單。

1. 按下「Alt」+「F11」，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 點選「插入」>「模組」，並將下列 VBA 程式碼貼上至新開啟的模組視窗中。

VBA：將 Outlook 中指定新建郵件的資料夾與子資料夾清單匯出

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. 按下「F5」鍵執行 VBA。

4. 在彈出的「選取資料夾」對話方塊中，選取您要列印其資料夾清單的電子郵件帳戶，然後按一下「確定」。

5. 所選帳戶的資料夾清單將如圖所示複製到新建郵件中。請點選「檔案」>「列印」，即可列印該資料夾清單。

6. 列印完成後，關閉新郵件且不儲存。

---

將所有 Outlook 資料夾及其子資料夾的清單匯出並列印至記事本

此方法介紹一個 VBA 腳本，能將指定電子郵件帳戶在 Outlook 中的所有資料夾與子資料夾清單匯出至記事本，方便您輕鬆列印。

1. 按下「Alt」+「F11」，即可開啟 Microsoft Visual Basic for Applications 視窗。

2. 點選「插入」>「模組」，並將下列 VBA 程式碼貼上至新開啟的模組視窗中。

VBA：將所有 Outlook 資料夾與子資料夾清單從 Outlook 匯出至記事本

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. 按下「F5」執行 VBA。在開啟的「選取資料夾」對話方塊中，選取您要匯出並列印資料夾清單的電子郵件帳戶，然後按一下「確定」。

4。「輸出資料夾樹狀結構」對話方塊將出現。若您希望包含樹狀縮排，請點選「是」；否則，請點選「否」。

現在，名為「Outlook-Folders」的純文本已建立並儲存於您的桌面，如下圖所示：

5. 雙擊開啟新的純文字檔，然後點選「檔案」>「列印」，即可列印已匯出的 Outlook 資料夾清單。

相關文章

在 Outlook 中顯示或隱藏資料夾清單檢視