如何在Outlook日曆中搜索和替換約會主題？

Author: Siluvia Last Modified: 2025-08-06

當你需要將某些主題替換為相同文字時，或者在Outlook數據導入後需要替換主題字段中的“Copy”一詞時，使用Outlook日曆中的查找和替換功能非常有用。本文提供了一段VBA代碼來幫助你搜索和替換多個約會主題。請瀏覽更多詳細信息。

使用VBA代碼搜索和替換約會主題

使用VBA代碼搜索和替換約會主題

在本節中，你可以按照以下步驟使用VBA代碼搜索和替換約會主題。

1. 首先，你需要在Outlook中將宏設置調整為低安全性。

1) 在Outlook 2010和2013中，點擊「文件」>「選項」。在「Outlook選項」對話框中，點擊左側的「信任中心」，然後點擊「信任中心設置」按鈕。

在「信任中心」對話框中，點擊左側的「宏設置」，然後在「宏設置」部分選擇「啟用所有宏」選項，並點擊「確定」按鈕。參見截圖：

2) 在Outlook 2007中，請點擊「工具」>「信任中心」。在「信任中心」對話框中，點擊左側的「宏設置」，然後選擇「不檢查宏的安全性」選項，並點擊「確定」按鈕。

2. 按下「Alt」+「F11」鍵打開「Microsoft Visual Basic for Applications」窗口。

3. 在「Microsoft Visual Basic for Applications」窗口中，雙擊展開「project1」>「Microsoft Outlook Objects」>「ThisOutlookSession」以打開VBA編輯器。參見截圖：

4. 複製並將以下VBA代碼粘貼到VBA編輯器中。然後按下「F5」鍵運行代碼。

VBA：查找和替換約會主題

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. 運行代碼後，會彈出一個「Microsoft Outlook」對話框。點擊「確定」按鈕。