如何在 Outlook 中取得資料夾清單？

有時，導航窗格中完整顯示所有郵件資料夾（包括您自行建立的個人資料夾）的樹狀結構，能幫助 Outlook 使用者更順暢地完成工作。若想快速列出完整的資料夾樹狀結構，可透過 VBA 程式碼輕鬆達成。本教學將引導您如何運用 VBA 程式碼，迅速取得這份資料夾清單。

使用 VBA 程式碼在 Outlook 中取得資料夾清單

---

使用 VBA 程式碼在 Outlook 中取得資料夾清單

若要透過 VBA 程式碼在 Outlook 中取得資料夾清單，請依下列步驟操作。

1. 按下鍵盤上的「Alt」+「F11」，即可開啟「Microsoft Visual Basic for Applications」視窗。

2. 接著雙擊「Project 1」>「Microsoft Outlook 物件」>「ThisOutlookSession」，即可開啟「Project 1 – ThisOutlookSession」視窗。請參閱截圖：

3. 接著，將下方的 VBA 程式碼複製並貼上至「Project 1 – ThisOutlookSession」視窗中。

VBA：在 Outlook 中取得資料夾清單

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. 按下鍵盤上的「F5」鍵，立即執行 VBA 程式碼。

5. 此時將彈出「巨集」對話方塊，請點擊「執行」按鈕。

6. 巨集執行完畢後，所有電子郵件資料夾的清單將立即顯示於一個全新的郵件視窗中，方便您輕鬆列印。請參閱截圖：

注意：此 VBA 程式碼適用於 Outlook 2007、2010 與 2013.