在 Excel 中，雖然 IF 函數對於基本邏輯測試至關重要，但複雜的條件通常需要巢狀 IF 語句來增強資料處理。在本綜合指南中，我們將詳細介紹嵌套 IF 的基礎知識，從語法到實際應用，包括嵌套 IF 與 AND/OR 條件的組合。此外，我們還將分享如何提高嵌套 IF 函數的可讀性以及有關嵌套 IF 的一些技巧，並探索 VLOOKUP、IFS 等強大的替代方案，使複雜的邏輯運算更易於使用和更有效率。

• 嵌套 IF 的語法
• 嵌套 IF 的實際例子
• 嵌套 if 與 AND / OR 條件

• 使嵌套 IF 易於閱讀
• 嵌套 IF 函數的順序
• 數字和文字應該區別對待
• 嵌套 IF 的局限性

• 使用 VLOOKUP
• 使用 IFS
• 使用選擇和匹配

Excel IF 函數與巢狀 IF 語句

Excel 中的 IF 函數和巢狀 IF 語句具有相似的用途，但其複雜度和應用程式有顯著差異。

嵌套 IF 的用法

本節示範 Excel 中巢狀 IF 語句的基本用法，包括語法、實際範例以及如何將它們與 AND 或 OR 條件一起使用。

嵌套 IF 的語法

了解函數的語法是在 Excel 中正確有效應用函數的基礎。讓我們從嵌套 if 語句的語法開始。

句法:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

參數:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

請記住，在嵌套 IF 結構中，只有當前面的所有條件均為 FALSE 時，才會計算每個後續條件。這種順序檢查對於理解嵌套 IF 的工作原理至關重要。

嵌套 IF 的實際例子

現在，讓我們透過兩個實際範例深入探討嵌套 IF 的使用。

範例 1：評分系統

如下面的螢幕截圖所示，假設您有一個學生分數列表，並希望根據這些分數分配成績。您可以使用巢狀 IF 來完成此任務。

選擇一個空白儲存格（本例為 C2），輸入以下公式並按 Enter 得到結果。然後拖曳 填充手柄 下來得到其餘的結果。

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

範例2：銷售佣金計算

想像一下這樣一個場景：銷售代表根據其銷售業績獲得不同的佣金率。如下圖所示，您想要根據這些不同的銷售門檻計算銷售人員的佣金，而嵌套 IF 語句可以幫助您實現此目的。

選擇一個空白儲存格（本例為 C2），輸入以下公式並按 Enter 得到結果。然後拖曳 填充手柄 下來得到其餘的結果。

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

嵌套 if 與 AND / OR 條件

在本節中，我修改上面的第一個範例「評分系統」來示範如何在 Excel 中將巢狀 IF 與 AND 或 OR 條件結合。在修改後的評分範例中，我引入了一個基於「出勤率」的附加條件。

使用嵌套 if 和 A​​ND 條件

如果學生同時滿足分數和出席標準，他們將獲得成績提升。例如，成績達到60分以上且出席率達95%以上的學生，其成績將提升一級，如從A升到A+、B升到B+等。但如果出席率低於95%，則以原來的分數標準進行評分。在這種情況下，我們需要使用帶有 AND 條件的巢狀 IF 語句。

選擇一個空白儲存格（本例為 D2），輸入以下公式並按 Enter 得到結果。然後拖曳 填充手柄 下來得到其餘的結果。

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

使用嵌套 if 和 OR 條件

在這種情況下，如果學生的成績達到 95 分或以上，或出席率達到 95% 或以上，則其成績將提高一級。以下是我們如何使用嵌套 IF 和 OR 條件來完成它。

選擇一個空白儲存格（本例為 D2），輸入以下公式並按 Enter 得到結果。然後拖曳 填充手柄 下來得到其餘的結果。

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

嵌套 IF 的提示和技巧

本節介紹嵌套 IF 的四個有用的提示和技巧。

使嵌套 IF 易於閱讀

典型的巢狀 IF 語句可能看起來很緊湊，但可能很難解讀。

在下面的公式中，快速確定一個條件在哪裡結束、另一個條件從哪裡開始是一項挑戰，尤其是隨著複雜性的增加。

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

解決方案：新增換行符號和縮排

為了使巢狀 IF 易於閱讀，您可以將公式分成多行，每個巢狀 IF 佔一個新行。在公式中，只需將遊標放在 IF 之前，然後按 Alt + Enter 鍵即可。

將上面的公式拆解後，如下圖：

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

這種格式使每個條件和相應輸出的位置更加清晰，從而增強了公式的可讀性。

嵌套 IF 函數的順序

嵌套 IF 公式中邏輯條件的順序至關重要，因為它決定了 Excel 如何計算這些條件，從而影響公式的最終結果。

正確的公式

在評分系統範例中，我們使用以下公式根據分數分配等級。

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel 依序計算嵌套 IF 公式中的條件（從第一個條件到最後一個條件）。此公式首先檢查最高分數閾值（“A”>=90），然後移至較低閾值。它確保將分數與其符合資格的最高等級進行比較。如果第一個條件為真 (A2>=90)，則傳回「A」且不評估任何其他條件。

順序公式不正確

如果條件順序顛倒，從最低閾值開始，它將傳回錯誤的結果。

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

在這個不正確的公式中，95 分將立即滿足第一個條件 B2>=60，並被錯誤地分配為等級“D”。

數字和文字應該區別對待

本節將向您展示如何在巢狀 IF 語句中以不同的方式處理數字和文字。

民數記

數字用於算術比較和計算。在巢狀 IF 語句中，您可以使用 >、<、=、>= 和 <= 等運算子直接比較數字。

文本

在巢狀 IF 語句中，文字應該是 用雙引號括起來。見下式中的A、B、C、D、F：

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

嵌套 IF 的局限性

本節列出了嵌套 IF 的幾個限制和缺點。

複雜性和可讀性：

儘管 Excel 允許您嵌套最多 64 個不同的 IF 函數，但完全不建議這樣做。嵌套層數越多，公式就越複雜。這可能會導致公式難以閱讀、理解和維護。

容易出錯：

此外，複雜的巢狀 IF 語句可能容易出錯，且難以除錯或修改。

難以擴展或擴展：

如果您的邏輯發生變化或需要添加更多條件，則深層嵌套的 IF 可能難以修改或擴展。

了解這些限制是在 Excel 中有效使用巢狀 IF 語句的關鍵。通常，將巢狀 IF 與其他函數結合或尋求替代方法可以產生更有效率且可維護的解決方案。

嵌套 IF 的替代方案

本節列出了 Excel 中可用作巢狀 IF 語句替代方法的多個函數。

使用 VLOOKUP

您可以使用VLOOKUP函數代替巢狀的IF語句來完成上述兩個實際範例。您可以這樣做：

範例 1：使用 VLOOKUP 的評分系統

這裡我將展示如何使用VLOOKUP根據分數分配成績。

第 1 步：建立成績查找表

首先，您需要為分數範圍和相應的等級建立一個查找表（例如本例中的E1:F6）。 備註: 表第一列中的分數必須按升序排序。

步驟 2：應用 VLOOKUP 函數分配成績

選擇一個空白儲存格（本例為 C2），輸入以下公式並按 Enter 獲得第一名的關鍵。選擇此公式儲存格並將其拖曳 填充手柄 下來獲得其餘的成績。

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

範例2：使用VLOOKUP計算銷售佣金

您也可以使用VLOOKUP在Excel中完成銷售佣金計算。請按以下步驟操作。

第 1 步：建立成績查找表

首先，您需要建立一個銷售額和相應佣金率的查找表，例如本例中的 E2:F4。 備註：表格第一列的銷售額必須依升序排序。

步驟 2：應用 VLOOKUP 函數分配成績

選擇一個空白儲存格（本例中為 C2），輸入以下公式並按 Enter 鍵以獲得第一個佣金。選擇此公式單元格並向下拖曳其填充手柄以獲得其餘結果。

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

使用 IFS

IFS函數 透過消除嵌套需求簡化了流程，並使公式更易於閱讀和管理。它增強了可讀性並簡化了多個條件檢查的處理。若要使用 IFS 函數，請確保您使用的是 Excel 2019 或更高版本，或擁有 Office 365 訂閱。讓我們看看如何將其應用到實際範例中。

範例 1：使用 IFS 的評分系統

假設評分標準與之前相同，則可以如下使用 IFS 函數：

選擇一個空白儲存格，例如C2，輸入以下公式並按 Enter 得到第一個結果。選擇該結果儲存格並將其拖曳 填充手柄 下來得到其餘的結果。

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

範例 2：使用 IFS 計算銷售佣金

對於銷售佣金計算場景，應用IFS函數如下：

選擇一個空白儲存格，例如C2，輸入以下公式並按 Enter 得到第一個結果。選擇該結果儲存格並將其拖曳 填充手柄 下來得到其餘的結果。

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

使用選擇和匹配

與巢狀 IF 語句相比，CHOOSE 和 MATCH 方法更有效率且更易於管理。此方法簡化了公式並使更新或更改更加簡單。下面我將示範如何使用 CHOOSE 和 MATCH 函數的組合來處理本文中的兩個實際範例。

範例 1：使用 CHOOSE 和 MATCH 的評分系統

您可以使用 CHOOSE 和 MATCH 功能的組合來根據不同的分數分配等級。

第 1 步：使用搜尋值建立查找數組

首先，您需要建立一個包含 MATCH 將搜尋的閾值的儲存格範圍，例如本例中的 $E$2:$E$6。 備註: 使用近似匹配類型時，此範圍內的數字必須按升序排序，MATCH 函數才能正常運作。

第 2 步：應用選擇和配對來分配成績

選擇一個空白儲存格（本例為 C2），輸入以下公式並按 Enter 獲得第一名的關鍵。選擇此公式儲存格並將其拖曳 填充手柄 下來得到其餘的結果。

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

範例 2：使用 IFS 計算銷售佣金

使用 CHOOSE 和 MATCH 組合進行銷售佣金計算也很有效，特別是當佣金率是基於指定的銷售門檻時。讓我們看看我們能做什麼。

第 1 步：使用搜尋值建立查找數組

首先，您需要建立一個包含 MATCH 將搜尋的閾值的儲存格範圍，例如本例中的 $E$2:$E$4。 備註: 使用近似匹配類型時，此範圍內的數字必須按升序排序，MATCH 函數才能正常運作。

步驟 2： 應用 CHOOSE 和 MATCH 以獲得結果

選擇一個空白儲存格（本例為 C2），輸入以下公式並按 Enter 獲得第一名的關鍵。選擇此公式儲存格並將其拖曳 填充手柄 下來得到其餘的結果。

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

總而言之，掌握 Excel 中的巢狀 IF 語句是一項寶貴的技能，可以增強您在資料分析和決策過程中處理複雜邏輯場景的能力。雖然嵌套 IF 對於複雜的邏輯運算非常強大，但請務必注意它們的局限性。 VLOOKUP、IFS 和 CHOOSE with MATCH 等更簡單的替代方案可以在某些情況下提供更簡化的解決方案。有了這些見解，您現在可以自信地將最合適的 Excel 技術應用於您的資料分析任務，確保電子表格的清晰度、準確性和效率。對於那些渴望深入研究 Excel 功能的人，我們的網站擁有豐富的教學。 在這裡了解更多 Excel 提示和技巧.

相關文章