跳到主要內容

如何在 Excel 中創建動態前 10 或第 n 列表?

頂級列表用於根據價值觀對公司或個人進行排名。 假設您有一個班級學生成績的列表,現在,您想創建一個動態的前 10 名學生列表,如下圖所示。 在本文中,我將介紹一些用於在 Excel 工作表中創建前 10 或 n 列表的公式。


在 Excel 中創建動態前 10 名列表

在 Excel 2019 及更早版本中,要提取前 10 名列表或帶條件的前 10 名列表,應應用以下公式:

創建動態前 10 名列表的公式

1. 首先,您應該從數據范圍中提取前 10 個值,請使用下面的公式進入空白單元格 - G2,然後向下拖動填充柄以獲得前 10 個值,見截圖:

=LARGE($B$2:$B$20,ROWS(B$2:B2))
備註:在此公式中, B2:B20 是要獲取前 10 個值的數據列表,並且 B2 是數據列表的第一個單元格。

2. 然後,繼續將以下公式應用於單元格 - F2,然後按 Ctrl + Shift + Enter 鍵在一起以獲得第一個結果,請參見屏幕截圖:

=INDEX($A$2:$A$20,SMALL(IF($B$2:$B$20=G2,ROW($B$2:$B$20)-ROW($B$1)),COUNTIF($G$2:G2,G2)))
備註:在以上公式中, A2:A20 是您要從中提取前 10 個值的名稱的數據列表, B2:B20 是包含所有值的數據列表, G2 是從列中提取的最大值的單元格 BB1 是值列表的標題單元格。

3.得到第一個結果後,選擇公式單元格並向下拖動填充柄以立即獲取其他名稱,見截圖:


使用標準創建動態前 10 名列表的公式

有時,您可能需要根據標準獲得前 10 名。 例如,要獲得 Class10 的前 1 名姓名和分數,如下圖所示。

1. 要獲得前 10 名,您還需要使用以下公式提取前 10 名:

=LARGE(IF($B$2:$B$25=$F$2,$C$2:$C$25),ROW(I2)-ROW(I$1))

2。 然後按 Ctrl + Shift + Enter 鍵一起獲得第一個結果,然後將此公式向下拖動以顯示其他值,見截圖:

3. 然後,請將以下公式複制並粘貼到單元格 - I2 中,然後按 Ctrl + Shift + Enter 鍵同時提取第一個結果,然後將此公式拖動到其他單元格中,並顯示前 10 個名稱,如下圖所示:

=INDEX($A$2:$A$25,SMALL(IF(($C$2:$C$25=J2)*($B$2:$B$25=$F$2),ROW($C$2:$C$25)-ROW($C$1)),COUNTIF(J2:$J$2,J2)))

在 Office 10 中創建動態前 365 名列表

上面的公式我們可能很難理解,如果你使用的是 Office 365,它的 INDEX、SORT 和 SEQUENCE 函數,你可以創建簡單的公式來完成這個任務。

創建動態前 10 名列表的公式

要獲取數據列表,請使用以下公式:

=INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2})

然後,只需按下 Enter 鍵,前10名列表的所有數據一次顯示,見截圖:

保養竅門:

排序功能:

=排序(數組,[sort_index],[sort_order],[by_col])

  • 排列:要排序的單元格範圍;
  • [排序索引]: 排序到數組的列或行號。 例如,要按數據范圍的第二列排序,排序索引將為 2;
  • [排序]:數字1(或省略)表示按升序排序; 數字-1,降序排列;
  • [按_col]: 排序的方向。 TRUE,按列排序,FALSE 或省略,按行排序。

在公式中,我們使用 SORT 函數:

排序(A2:B20,2,-1): 表示按降序對第二列的單元格範圍 A2:A20 進行排序。


序列功能:

=SEQUENCE(行,[列],[開始],[步驟])

  • :要返回的行數,
  • [列]:要返回的列數。 如果省略,它將返回單列。
  • [開始]: 序列中的第一個數字。 如果省略,它將從 1 開始。
  • [步]:每個數字之間的增量。 如果排除,每個增量將為 1。

在這個公式中,我們使用 SEQUENCE(10) 創建一個從 1 到 10 的列表。

最後,將 SORT 和 SEQUENCE 函數都放入 INDEX 函數中: =INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2}),這將返回數據范圍的前 10 條記錄並返回第 1 列和第 2 列。


使用標準創建動態前 10 名列表的公式

要顯示帶有條件的前 10 個列表,您應該將 FILTER 函數嵌入到 SORT 函數中,如下所示:

=INDEX(SORT(FILTER(A2:C25,B2:B25=F2),3,-1),SEQUENCE(10),{1,3})

只需按下 Enter 鍵,一次顯示所有基於給定條件的前 10 名列表的數據,見截圖:

保養竅門:

過濾器功能:

=過濾器(數組,包括,[if_empty])

  • 排列:要過濾的單元格範圍。
  • 包括: 用於過濾數組的條件,以獲得 TRUE 或 FALSE 結果的數組,以便 TRUE 值將保留在過濾器中。
  • [如果_空]: 沒有匹配結果時顯示的值。

在這個公式中: =FILTER(A2:C25,B2:B25=F2) 用於過濾範圍 A2:C25,其中 B2:B25 中的值等於特定單元格 F2。

最佳辦公生產力工具

熱門特色: 尋找、突出顯示或識別重複項   |  刪除空白行   |  合併列或儲存格而不遺失數據   |   沒有公式的回合 ...
超級查詢: 多條件VLookup    多值VLookup  |   跨多個工作表的 VLookup   |   模糊查詢 ....
高級下拉列表: 快速建立下拉列表   |  依賴下拉列表   |  多選下拉列表 ....
欄目經理: 新增特定數量的列  |  移動列  |  切換隱藏列的可見性狀態  |  比較範圍和列 ...
特色功能: 網格焦點   |  設計圖   |   大方程式酒吧    工作簿和工作表管理器   |  資源庫 (自動文字)   |  日期選擇器   |  合併工作表   |  加密/解密單元格    按清單發送電子郵件   |  超級濾鏡   |   特殊過濾器 (過濾粗體/斜體/刪除線...)...
前 15 個工具集12 文本 工具 (添加文本, 刪除字符,...)   |   50+ 圖表 類型 (甘特圖,...)   |   40+ 實用 公式 (根據生日計算年齡,...)   |   19 插入 工具 (插入二維碼, 從路徑插入圖片,...)   |   12 轉化 工具 (數字到單詞, 貨幣兌換,...)   |   7 合併與拆分 工具 (高級合併行, 分裂細胞,...)   |   ... 和更多

使用 Kutools for Excel 增強您的 Excel 技能,體驗前所未有的效率。 Kutools for Excel 提供了 300 多種進階功能來提高生產力並節省時間。  點擊此處獲取您最需要的功能...

kte選項卡201905


Office選項卡為Office帶來了選項卡式界面,使您的工作更加輕鬆

  • 在Word,Excel,PowerPoint中啟用選項卡式編輯和閱讀,發布者,Access,Visio和Project。
  • 在同一窗口的新選項卡中而不是在新窗口中打開並創建多個文檔。
  • 將您的工作效率提高 50%,每天為您減少數百次鼠標點擊!
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations