如何在 Excel 中使用兩個或多個條件查找值？

假設您有一個如下截圖所示的水果銷售表，您需要根據多個條件找出數量值。這裡，本方法將介紹一些陣列公式，以便根據這些給定的條件輕鬆找出值。

陣列公式 1：在 Excel 中根據兩個或多個條件查找值

此陣列公式的基本表達式如下所示：

{=INDEX(array,MATCH(1,(criteria 1=lookup_array 1)*(criteria 2= lookup_array 2)…*(criteria n= lookup_array n),0))}

假設您想查找 2019 年 9 月 3 日出現的芒果銷售數量，您可以將以下陣列公式輸入到空白單元格中，然後同時按下 Ctrl + Shift + Enter 鍵。

=INDEX(F3:F22,MATCH(1,(J3=B3:B22)*(J4=C3:C22),0))

備註：在上述公式中，F3:F22 是您要查找值的「數量」列，B3:B22 是「日期」列，C3:C22 是「水果」列，J3 是作為第一個條件給出的日期，J4 是作為第二個條件給出的水果名稱。

根據陣列公式的表達式，您可以根據需要輕鬆添加條件。例如，如果您現在正在查找 2019 年 9 月 3 日出現且重量為 211 的芒果銷售數量，您可以在 MATCH 部分中添加條件和查找範圍如下：

=INDEX(F3:F22,MATCH(1,(J3=B3:B22)*(J4=C3:C22)*(J5=E3:E22),0))

然後按下 Ctrl + Shift + Enter 鍵來找出銷售數量。

陣列公式 2：在 Excel 中根據兩個或多個條件查找值

此陣列公式的基本表達式如下所示：

=INDEX(array,MATCH(criteria1& criteria2…& criteriaN, lookup_array1& lookup_array2…& lookup_arrayN,0),0)

例如，您想查找重量為 242 且發生在 2019 年 9 月 1 日的水果銷售數量，您可以將以下公式輸入到空白單元格中，並同時按下 Ctrl + Shift + Enter 鍵。

=INDEX(F3:F22,MATCH(J3&J4,B3:B22&C3:C22,0),0)

備註：在上述公式中，F3:F22 是您要查找值的「數量」列，B3:B22 是「日期」列，E3:E22 是「重量」列，J3 是作為第一個條件給出的日期，J5 是作為第二個條件給出的重量值。

如果您想根據三個或更多條件查找值，可以輕鬆地在 MATCH 部分中添加您的條件和查找範圍。請注意，條件和查找範圍必須按相同順序排列。

例如，您想查找重量為 242 且發生在 2019 年 9 月 1 日的梨子銷售數量，您可以如下添加條件和查找範圍：

=INDEX(F3:F22,MATCH(J3&J4&J5,B3:B22&C3:C22&E3:E22,0),0)

然後按下 Ctrl + Shift + Enter 鍵來計算銷售數量。

除了公式之外，您還可以應用進階篩選器功能來查找 Excel 中符合兩個或多個條件的所有值。請按照以下步驟操作：

1. 點擊 數據 > 進階 以啟用進階篩選器功能。

2. 在進階篩選器對話框中，請執行以下操作：
(1) 在「操作」部分中勾選「 複製到其他位置」選項；
(2) 在「 列表範圍」框中，選擇您要查找值的範圍（在我的情況下為 A1:E21）；
(3) 在「 條件範圍」框中，選擇您要根據其查找值的範圍（在我的情況下為 H1:J2）；
(4) 在「複製到」框中，選擇目標範圍的第一個單元格，您將放置篩選後的行（在我的情況下為 H9）。

3. 點擊 確定 按鈕。

現在，與所有列出條件匹配的篩選行已被複製並放置在目標範圍內。請參見截圖：