在Excel中鍵入時如何自動完成文本框？

默認情況下，Excel可以記住您在當前工作表的單元格中輸入的內容，並在下次在新的單元格中鍵入相關的首字母時自動完成此內容。 但是，如果要使在工作表中輸入的所有內容都可以在文本框（ActiveX控件）中自動完成，該怎麼辦？ 本文將提供一種VBA方法，以幫助您在其中鍵入首字母時自動完成文本框。

使用VBA代碼鍵入時自動完成文本框

使用VBA代碼鍵入時自動完成文本框

請執行以下操作以使文本框在文本框中鍵入首字母時自動完成。

1.請點擊插入一個文本框 開發者 > 插入 > 文本框（ActiveX控件）。 看截圖：

2.然後單擊 開發者 > 插入 > 列錶框（ActiveX控件） 在當前工作表中插入一個列錶框。 看截圖：

3.右鍵單擊工作表選項卡，然後單擊 查看代碼 從上下文菜單中，如下所示。

4。 在裡面 Microsoft Visual Basic for Applications 窗口，請將下面的VBA代碼複製並粘貼到“代碼”窗口中。 然後點擊 工具 > 參考，然後檢查 Microsoft腳本運行時 盒子裡 參考– VBAProject 對話框。 看截圖：

VBA代碼：鍵入時自動完成文本框

Dim xRg As Range
Dim xDic As New Dictionary
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Me.TextBox1.Value = Me.ListBox1.Value
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xVal As String
    On Error Resume Next
    If IsNumeric(Target.Value) Then
        xVal = Str(Target.Value)
    Else
        xVal = Target.Value
    End If
    If xVal <> "" Then
        If Not xDic.Exists(xVal) Then
            xDic.Add xVal, xVal
        End If
    End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Me.ListBox1.Visible = False
End Sub
Private Sub Worksheet_Activate()
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    If xRg Is Nothing Then
        Set xRg = ActiveSheet.UsedRange
    End If
    Me.ListBox1.Visible = False
    xDic.RemoveAll
    With Me.ListBox1
        For I = 1 To xRg.Count
            xStr = xRg(I).Value
            If xStr <> "" Then
                .AddItem xStr
                If Not xDic.Exists(xStr) Then
                    xDic.Add xStr, xStr
                End If
            End If
        Next
    End With
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With Me.ListBox1
        .Top = Me.TextBox1.Top
        .Left = Me.TextBox1.Left + Me.TextBox1.Width
        .Width = Me.TextBox1.Width
    End With
    TextBoxVal Me.TextBox1.Object
End Sub
Sub TextBoxVal(xTextBox As Variant)
    Dim I As Long
    Dim xStr As String
    On Error Resume Next
    Application.ScreenUpdating = False
    If xRg Is Nothing Then Exit Sub
    Me.ListBox1.Clear
    xStr = xTextBox.Value
    If xStr = "" Then
        Me.ListBox1.Visible = False
        Application.EnableEvents = True
        Exit Sub
    End If
    For I = 0 To UBound(xDic.Items)
        If Left(xDic.Items(I), Len(xStr)) = xStr Then
            Me.ListBox1.AddItem xDic.Items(I)
        End If
    Next
    Me.ListBox1.Visible = True
    If Me.ListBox1.ListCount > 0 Then
        With xTextBox
            .Value = Me.ListBox1.List(0)
            .SelStart = Len(xStr)
            .SelLength = Len(Me.ListBox1.List(0))
        End With
    End If
    Me.ListBox1.Activate
    Me.ListBox1.Selected(0) = True
    Application.ScreenUpdating = True
End Sub
Private Sub ListBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Me.TextBox1.Value = Me.ListBox1.Value
    End If
End Sub

備註：在代碼中， ListBox1 文字框1 是您已插入工作表中的列錶框和文本框的名稱。

5。 按 其他 + Q 退出鍵 Microsoft Visual Basic for Applications 窗口。

6.通過單擊關閉設計模式 開發者 > 設計模式 在工作表中。

7.現在轉到另一個工作表，然後返回到上一個工作表以啟用VBA代碼。

從現在開始。 在文本框中輸入首字母時，所有以您在工作表中輸入的字母開頭的文本都將列在文本框右側的列錶框中。 請雙擊所需的一個，將其輸入文本框。 看截圖：

備註：你可以使用 Up or 下 箭頭鍵在列錶框中的所有自動完成文本之間移動，然後按 Enter 鍵，將所需的一個輸入文本框。

相關文章：

• 在Excel中選擇文本框時如何自動選擇文本？
• 在Excel中單擊時如何清除文本框的內容？
• 如何將多個單元格的文本連接到Excel中的文本框中？
• 如何禁用文本框中的編輯以防止用戶在Excel中輸入？
• 如何在Excel中將文本框設置為百分比格式？