如何根據Excel中的單元格列表重命名資料夾中的所有圖片文件？

您是否曾經需要根據Excel工作表中的名稱列表來重命名資料夾中的多張圖片？一一手動重命名可能會非常耗時，但借助VBA代碼，您可以快速自動化這個過程。

重命名資料夾中的所有圖片文件

重命名資料夾中的所有圖片文件

要重命名指定資料夾中的所有圖片文件，請按照以下步驟操作：

步驟1：將資料夾中的原始文件名導入到Excel的工作表中

1. 按下「Alt + F11」鍵以啟用「Microsoft Visual Basic for Applications」視窗。

2. 點擊「插入」>「模組」，並將以下代碼粘貼到腳本中。

VBA：從資料夾中獲取圖片名稱

Sub PictureNametoExcel()
'UpdatebyExtendoffice201709027
    Dim I As Long
    Dim xRg As Range
    Dim xAddress As String
    Dim xFileName As String
    Dim xFileDlg As FileDialog
    Dim xFileDlgItem As Variant
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Select a cell to place name list:", "KuTools For Excel", xAddress, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Set xRg = xRg(1)
    xRg.Value = "Picture Name"
    With xRg.Font
    .Name = "Arial"
    .FontStyle = "Bold"
    .Size = 10
    End With
    xRg.EntireColumn.AutoFit
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    I = 1
    If xFileDlg.Show = -1 Then
        xFileDlgItem = xFileDlg.SelectedItems.Item(1)
        xFileName = Dir(xFileDlgItem & "\")
        Do While xFileName <> ""
            If InStr(1, xFileName, ".jpg") + InStr(1, xFileName, ".png") + InStr(1, xFileName, ".img") + InStr(1, xFileName, ".gif") + InStr(1, xFileName, ".ioc") + InStr(1, xFileName, ".bmp") > 0 Then
                xRg.Offset(I).Value = xFileDlgItem & "\" & xFileName
                I = I + 1
            End If
            xFileName = Dir
        Loop
    End If
    Application.ScreenUpdating = True
End Sub

3. 按下「F5」鍵運行代碼，會彈出一個對話框提醒您選擇一個單元格以輸出名稱列表。參見截圖：

4. 點擊「確定」，並選擇需要列出圖片名稱的指定資料夾於當前工作表中。參見截圖：

5. 點擊「確定」，圖片名稱已列在當前工作表上。

步驟2：根據新的名稱列表重命名圖片文件

1. 按下「Alt + F11」鍵以啟用「Microsoft Visual Basic for Applications」視窗。

2. 點擊「插入」>「模組」，並將以下代碼粘貼到腳本中。

VBA：重命名資料夾中的圖片文件

Sub RenameFile()
'UpdatebyExtendoffice20170927
    Dim I As Long
    Dim xLastRow As Long
    Dim xAddress As String
    Dim xRgS, xRgD As Range
    Dim xNumLeft, xNumRight As Long
    Dim xOldName, xNewName As String
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xRgS = Application.InputBox("Select Original Names(Single Column):", "KuTools For Excel", xAddress, , , , , 8)
    If xRgS Is Nothing Then Exit Sub
    Set xRgD = Application.InputBox("Select New Names(Single Column):", "KuTools For Excel", , , , , , 8)
    If xRgD Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    xLastRow = xRgS.Rows.Count
    Set xRgS = xRgS(1)
    Set xRgD = xRgD(1)
    For I = 1 To xLastRow
        xOldName = xRgS.Offset(I - 1).Value
        xNumLeft = InStrRev(xOldName, "\")
        xNumRight = InStrRev(xOldName, ".")
        xNewName = xRgD.Offset(I - 1).Value
        If xNewName <> "" Then
            xNewName = Left(xOldName, xNumLeft) & xNewName & Mid(xOldName, xNumRight)
            Name xOldName As xNewName
        End If
    Next
    MsgBox "Congratulations! You have successfully renamed all the files", vbInformation, "KuTools For Excel"
    Application.ScreenUpdating = True
End Sub

3. 按下「F5」鍵運行代碼，會彈出一個對話框提醒您選擇要替換的原始圖片名稱。參見截圖：

4. 點擊「確定」，並在第二個對話框中選擇要用來替換圖片名稱的新名稱。參見截圖：

5. 點擊「確定」，會彈出一個對話框提醒您圖片名稱已成功替換。

6. 點擊「確定」，資料夾中的圖片名稱將被替換為工作表中單元格的新名稱。

相關文章：

• 如何根據Excel中的單元格值重命名工作表？