如何在Excel中將特定文件從一個文件夾移動到另一個文件夾？

假設，我有一個大文件夾，其中包含各種文件，例如docx，jpg，xlsx等，如下面的屏幕快照所示。 現在，我想將某些特定的文件類型從文件夾移動到另一個新文件夾，而無需手動一個個地移動。 您有什麼好主意可以解決Excel中的此任務嗎？

使用VBA代碼將特定文件從一個文件夾移動到另一個文件夾

使用VBA代碼將特定文件從一個文件夾移動到另一個文件夾

若要將所有特定類型的文件從一個文件夾快速移動到另一個文件夾，以下VBA代碼可能會為您提供幫助：

1。 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 窗口。

2。 點擊 插入 > 模塊，然後將以下代碼粘貼到 模塊 窗口。

VBA代碼：將特定類型的文件從一個文件夾移動到另一文件夾：

Sub MoveFiles()
'Updateby Extendoffice
    Dim xFd As FileDialog
    Dim xTFile As String
    Dim xExtArr As Variant
    Dim xExt As Variant
    Dim xSPath As String
    Dim xDPath As String
    Dim xSFile As String
    Dim xCount As Long
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    xFd.Title = "Please select the original folder:"
    If xFd.Show = -1 Then
        xSPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xSPath, 1) <> "\" Then xSPath = xSPath + "\"
    xFd.Title = "Please select the destination folder:"
    If xFd.Show = -1 Then
        xDPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xDPath, 1) <> "\" Then xDPath = xDPath + "\"
    xExtArr = Array("*.xlsx*", "*.jpg")
    For Each xExt In xExtArr
        xTFile = Dir(xSPath & xExt)
        Do While xTFile <> ""
            xSFile = xSPath & xTFile
            FileCopy xSFile, xDPath & xTFile
            Kill xSFile
            xTFile = Dir
            xCount = xCount + 1
        Loop
    Next
    MsgBox "Total number of moved files is: " & xCount, vbInformation, "Kutools for Excel"
End Sub

備註：在上面的代碼中，“* .xlsx *“”* .JPG在腳本中： xExtArr = Array（“ *。xlsx *”，“ * .jpg”） 是您要移動的文件類型，您可以將它們更改為其他文件類型，或根據需要添加其他文件類型。

3。 然後按 F5 鍵以運行此代碼，並彈出一個窗口，提醒您選擇要從中移動文件的原始文件夾，請參見屏幕截圖：

4。 然後點擊 OK，然後會彈出另一個窗口，請選擇要將文件移動到的目標文件夾，請參見屏幕截圖：

5。 然後點擊 OK，將彈出一個提示框，提醒您已移動了多少文件，將其關閉，您可以看到特定的jpg，xlsx文件已移動到指定的文件夾，請參見屏幕截圖：