如何將工作表另存為 PDF 文件並通過 Outlook 作為附件發送？

在日常工作中，您可能經常需要與同事或客戶分享特定的工作表，但又希望確保文件格式固定且安全。通過 Outlook 將工作表作為 PDF 文件發送是一項常見的需求，特別是用於記錄報告、發送發票或分享不應輕易修改的最終數據時。傳統的做法是手動將工作表保存為 PDF，打開 Outlook，撰寫郵件，附加 PDF，然後發送——這個過程既繁瑣又耗時，尤其是在頻繁重複或處理多個工作表時。

本文將逐步指導您如何自動化將工作表轉換為 PDF 並將其直接從 Excel 附到 Outlook 郵件中的過程，幫助您節省大量時間並避免重複的手動操作。您會找到一個 VBA 程式碼解決方案，以及操作、優勢、應用場景和實用技巧的詳細介紹。

使用 VBA 程式碼將工作表另存為 PDF 文件並作為附件發送

使用 VBA 程式碼將工作表另存為 PDF 文件並作為附件發送

為了加快將 Excel 工作表匯出為 PDF 文件並通過 Outlook 發送的過程，您可以使用以下 VBA 程式碼。這種方法特別適用於需要定期從 Excel 直接發送個人化報告、發票或其他數據快照的情況，因為它完全自動化了保存和發送的步驟。

在應用此方法之前，請確保已安裝 Microsoft Outlook 並設置為您的默認郵件客戶端。當您的 Excel 環境中啟用了宏時，此程式碼的效果最佳。

1. 打開要保存並以 PDF 格式發送的工作表。同時按下 Alt + F11 啟動 Microsoft Visual Basic for Applications (VBA) 編輯器。

2. 在 VBA 視窗中，進入菜單並點擊 插入 > 模組。這將創建一個新的程式碼模組。然後將以下 VBA 程式碼複製並粘貼到模組的程式碼窗口中。  

VBA 程式碼：將工作表另存為 PDF 文件並作為附件發送

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" + xSht.Name + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file 
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email 
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

3. 粘貼程式碼後，按下 F5 或在 VBA 編輯器中點擊 執行 來執行宏。此時會彈出一個文件夾選擇對話框。選擇 PDF 文件應保存的目標文件夾，然後點擊 確定 以繼續。

4. 流程完成後，將生成一個新的 Outlook 郵件窗口，PDF 文件已附加。主題行預填了工作表名稱並以 ".pdf" 結尾；您可以編輯郵件內容，添加收件人，然後根據需要發送。這減少了錯誤並提高了效率，比手動附加更為高效。

當您需要定期分發最終版工作表作為 PDF 附件時，此基於 VBA 的方法最為高效，並最大限度地減少重複的手動步驟。其局限性包括依賴於 Outlook、無法一次性批量處理多個工作表，以及需要啟用宏。對於更複雜的工作流程（如一次性發送多個工作表或進行其他自動化），請考慮使用 Excel 外掛程式或內置功能。

替代解決方案：如果 VBA 宏不適合您的環境（例如宏受到限制），您可以手動使用 Excel 內置的 匯出 或 另存新檔 功能將工作表保存為 PDF，然後在 Outlook 中附加並發送。儘管此方法需要更多步驟，但它不需要特殊權限或腳本知識即可普遍使用。

相關文章：

• 如何將 Excel 文件名保存為帶時間戳的格式？
• 如何使用「另存新檔」功能自動覆蓋現有文件？
• 如何在 Excel 中將多個/全部工作表保存或匯出為分開的 CSV 或文本文件？
• 如何禁用或不允許在 Excel 中使用「保存」和「另存新檔」選項？
• 如何禁用工作簿保存，但只允許「另存新檔」？