如何根據背景顏色刪除 Excel 中的行？

您要如何根據背景顏色刪除整行呢？在這個例子中，我需要刪除所有單元格填充為藍色背景的行，如下方截圖所示。透過本文，您將獲得一些代碼來在 Excel 中完成此任務。

根據每個單元格的特定背景顏色刪除行

根據某一列的特定背景顏色刪除行

根據每個單元格的特定背景顏色刪除行

如果您有一組數據，其中某些單元格隨機填充了顏色，並且您需要刪除那些單元格顏色為藍色的行，如下方截圖所示：

要刪除此類型的行，您可以使用以下 VBA 代碼，請按照以下步驟操作：

1. 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組，並將以下代碼粘貼到 模組視窗中。

VBA 代碼：刪除包含特定填充顏色的單元格所在的行：

Sub DeleteRows()
'Updateby Extendoffice
    Dim rngCl As Range
    Dim xRows As Long
    Dim xCol As Long
    Dim colorLg As Long
    On Error Resume Next
    Set rngCl = Application.InputBox _
        (Prompt:="Select a cell with the background color to be deleted", _
        Title:="Kutools for Excel", Type:=8)
    On Error GoTo 0
    If rngCl Is Nothing Then
        MsgBox "User cancelled operation." & vbCrLf & _
        "Processing terminated", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    colorLg = rngCl.Interior.Color
    Application.ScreenUpdating = False
    With ActiveSheet.UsedRange
        For xRows = .Rows.Count To 1 Step -1
            For xCol = 1 To .Columns.Count
                           If .Cells(xRows, xCol).Interior.Color = colorLg Then
                    .Rows(xRows).Delete
                    Exit For
                End If
            Next xCol
        Next xRows
    End With
    Application.ScreenUpdating = True
End Sub

3. 然後按下 F5 鍵運行此代碼，將彈出一個提示框，提醒您選擇一個具有想要刪除的填充顏色的單元格，請參見截圖：

4. 然後點擊 確定，如果單元格包含特定填充顏色，則所有行都將被刪除。

根據某一列的特定背景顏色刪除行

如果您想僅根據某一列的特定顏色刪除行，例如，刪除 A 列中帶有藍色的行並得到下方截圖，這裡也有一段 VBA 代碼可以幫助您。

1. 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組，並將以下代碼粘貼到模組視窗中。

VBA 代碼：根據某一列中包含特定填充顏色的單元格刪除行：

Sub deleterow()
'UpdateBY Extendoffice
   Dim xRg As Range, rgDel As Range
    For Each xRg In ThisWorkbook.ActiveSheet.Range("A2:A21")
        If xRg.Interior.ColorIndex = 20 Then
            If rgDel Is Nothing Then
                Set rgDel = xRg
            Else
                Set rgDel = Union(rgDel, xRg)
            End If
        End If
    Next xRg
    If Not rgDel Is Nothing Then rgDel.EntireRow.Delete
End Sub

備註：在上述代碼中，A2:A21 是包含您希望刪除行所基於的特定填充顏色的列， ColorIndex = 20 腳本中的數字 20 是您希望刪除行所基於的顏色編號。您可以根據需要進行更改。

3. 然後按下 F5 鍵運行此代碼，A 列中包含藍色的所有行將立即被刪除。