如何在一個單元格範圍內加粗所有特定的單詞？

在 Excel 中，尋找和替換功能可以幫助我們找到任何特定的文字，並對整個單元格進行加粗或其他格式化。但是，您是否嘗試過只加粗單元格中的特定文字而不是整個單元格，如下方截圖所示：

使用 VBA 程式碼加粗單元格範圍內的所有特定單詞

使用 VBA 程式碼加粗單元格範圍內的所有特定單詞

以下 VBA 程式碼可能有助於您僅加粗單元格內容中的特定文字，請按照以下步驟操作：

1. 按住 ALT + F11 鍵以打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組，並將以下程式碼粘貼到模組視窗中。

VBA 程式碼：在單元格範圍內加粗特定文字

Sub FindAndBold()
'Updateby Extendoffice 20160711
    Dim xFind As String
    Dim xCell As Range
    Dim xTxtRg As Range
    Dim xCount As Long
    Dim xLen As Integer
    Dim xStart As Integer
    Dim xRg As Range
    Dim xTxt As String
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Please select data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    On Error Resume Next
    Set xTxtRg = Application.Intersect(xRg.SpecialCells(xlCellTypeConstants, xlTextValues), xRg)
    If xTxtRg Is Nothing Then
        MsgBox "There are no cells with text"
        Exit Sub
    End If
    xFind = Trim(Application.InputBox("What do you want to BOLD?", "Kutools for Excel", , , , , , 2))
    If xFind = "" Then
        MsgBox "No text was listed", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    xLen = Len(xFind)
    For Each xCell In xTxtRg
        xStart = InStr(xCell.Value, xFind)
        Do While xStart > 0
            xCell.Characters(xStart, xLen).Font.Bold = True
            xCount = xCount + 1
            xStart = InStr(xStart + xLen, xCell.Value, xFind)
        Loop
    Next
    If xCount > 0 Then
        MsgBox "number of " & CStr(xCount) & " text be bolded!", vbInformation, "Kutools for Excel"
    Else
        MsgBox "Not find the specific text!", vbInformation, "Kutools for Excel"
    End If
End Sub

3. 然後按 F5 鍵運行程式碼，會彈出一個提示框，提醒您選擇要加粗的資料區域，請參見截圖：

4. 接著點擊 確定，另一個對話框將彈出，提示您輸入只想在單元格中加粗的特定文字，請參見截圖：

5. 輸入文字後，請點擊 確定 按鈕，所有您指定的文字都已在選定範圍內被加粗，請參見截圖：