如何根據其他文字突出顯示單元格中的特定文字？

在 Excel 中，根據特定文字突出顯示單元格可能對我們來說很容易，但是，這裡我想突出顯示單元格內的特定文字以使其突出，而不是整個單元格。這對我們大多數人來說可能是一個麻煩。本文中，我將談談一些在 Excel 中解決此問題的技巧。

使用 VBA 程式碼突出顯示多個單元格內的一個或多個特定文字

使用一項驚人的功能突出顯示多個單元格內的一個或多個特定文字

使用 VBA 程式碼根據其他文字突出顯示單元格內的特定文字

使用 VBA 程式碼突出顯示多個單元格內的一個或多個特定文字

例如，我有一系列的文字字串，現在，我想在這些單元格中突出顯示特定文字“Sky”，以獲得如下截圖所示的結果：

要僅突出顯示單元格內的部分文字，以下 VBA 程式碼可以幫助您。

1. 選擇您想突出顯示特定文字的單元格，然後按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組，並將以下程式碼粘貼到模組視窗中。

VBA 程式碼：突出顯示單元格內的部分文字：

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
cFnd = InputBox("Enter the text string to highlight")
y = Len(cFnd)
For Each Rng In Selection
  With Rng
    m = UBound(Split(Rng.Value, cFnd))
    If m > 0 Then
      xTmp = ""
      For x = 0 To m - 1
        xTmp = xTmp & Split(Rng.Value, cFnd)(x)
        .Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
        xTmp = xTmp & cFnd
      Next
    End If
  End With
Next Rng
Application.ScreenUpdating = True
End Sub

3. 然後按下 F5 鍵運行程式碼，會彈出一個提示框提醒您輸入只想突出顯示的文字，請參閱截圖：

4. 然後點擊 確定 按鈕，所有您指定的文字都已在單元格內被突出顯示，請參閱截圖：

提示：如果您需要從文字字串中突出顯示多個關鍵字，請應用以下程式碼：
VBA 程式碼：從文字字串中突出顯示多個關鍵字：

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
Dim xFNum As Integer
Dim xArrFnd As Variant
Dim xStr As String
cFnd = InputBox("Please enter the text, separate them by comma:")
If Len(cFnd) < 1 Then Exit Sub
xArrFnd = Split(cFnd, ",")
For Each Rng In Selection
With Rng
For xFNum = 0 To UBound(xArrFnd)
xStr = xArrFnd(xFNum)
y = Len(xStr)
m = UBound(Split(Rng.Value, xStr))
If m > 0 Then
xTmp = ""
For x = 0 To m - 1
xTmp = xTmp & Split(Rng.Value, xStr)(x)
.Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
xTmp = xTmp & xStr
Next
End If
Next xFNum
End With
Next Rng
Application.ScreenUpdating = True
End Sub

然後，在彈出的框中，請輸入您想突出顯示的關鍵字（用逗號分隔），請參閱截圖：

然後，點擊 確定 按鈕，指定的文字已立即被突出顯示，請參閱截圖：

注意：上述程式碼區分大小寫。

使用一項驚人的功能突出顯示多個單元格內的一個或多個特定文字

如果您不熟悉 Excel 中的程式碼，這裡我將介紹一個簡單的工具 - Kutools for Excel，使用其標記關鍵字功能，您可以一次突出顯示單元格內的一個或多個特定關鍵字。

安裝 Kutools for Excel 後，請按照以下步驟操作：

1. 點擊 Kutools > 文本 > 標記關鍵字，請參閱截圖：

2. 在 標記關鍵字 對話框中，請進行以下操作：

• 從 區域 文本框中選擇您想使用的資料範圍；
• 選擇包含您想突出顯示的關鍵字的單元格，您也可以手動輸入關鍵字（用逗號分隔）到 關鍵字 文本框中
• 最後，您應該通過勾選 標記關鍵字顏色 選項來指定一種字體顏色以突出顯示文字。（要為包含關鍵字的整個單元格著色，選擇 標記儲存格內容顏色 選項）

3. 然後，點擊 確定 按鈕，所有指定的文字都已被突出顯示，如下截圖所示：

注意：此功能不區分大小寫，如果您想以區分大小寫的方式突出顯示文字，請在 標記關鍵字 對話框中勾選 區分大小寫。

使用 VBA 程式碼根據其他文字突出顯示單元格內的特定文字

這是另一種情況，我有兩列，第一列包含文字字串，第二列是特定文字，現在，我需要根據第二列中的特定文字突出顯示第一列中的相對應文字，每一行都要如此。

1. 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 視窗。

2. 點擊 插入 > 模組，並將以下程式碼粘貼到模組視窗中。

VBA 程式碼：根據其他文字突出顯示單元格內的部分文字：

Sub highlight()
'Updateby Extendoffice
    Dim xStr As String
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    Dim xChar As String
    Dim I As Long
    Dim J As Long
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
LInput:
    Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    If xRg.Areas.Count > 1 Then
        MsgBox "not support multiple columns"
        GoTo LInput
    End If
    If xRg.Columns.Count <> 2 Then
        MsgBox "the selected range can only contain two columns "
        GoTo LInput
    End If
    For I = 0 To xRg.Rows.Count - 1
        xStr = xRg.Range("B1").Offset(I, 0).Value
        With xRg.Range("A1").Offset(I, 0)
            .Font.ColorIndex = 1
            For J = 1 To Len(.Text)
                If Mid(.Text, J, Len(xStr)) = xStr Then .Characters(J, Len(xStr)).Font.ColorIndex = 3
            Next
        End With
    Next I
End Sub

3. 粘貼程式碼後，按下 F5 鍵運行它，會彈出一個提示框提醒您選擇包含文字字串和您想突出顯示並基於的特定文字的資料範圍，請參閱截圖：

4. 然後點擊 確定 按鈕，第一列中基於第二列特定文字的所有相對應文字都已被標紅色，如下截圖所示：

更多相關文章：