如何在另一個工作簿中查找/搜尋值？

在 VLOOKUP 函數中配置保存路徑、文件名和工作表可能會有些混亂。這種方法將介紹一種 VBA 來輕鬆解決這個問題。

1. 按 Alt + F11 鍵打開 Microsoft Visual Basic for Applications 窗口。

2. 點擊 插入 > 模塊，然後將以下 VBA 代碼粘貼到打開的模塊窗口中。

VBA：查找數據並從另一個關閉的工作簿返回值

Private Function GetColumn(Num As Integer) As String
If Num <= 26 Then
GetColumn = Chr(Num + 64)
Else
GetColumn = Chr((Num - 1) \ 26 + 64) & Chr((Num - 1) Mod 26 + 65)
End If
End Function
Sub FindValue()
Dim xAddress As String
Dim xString As String
Dim xFileName As Variant
Dim xUserRange As Range
Dim xRg As Range
Dim xFCell As Range
Dim xSourceSh As Worksheet
Dim xSourceWb As Workbook
On Error Resume Next
xAddress = Application.ActiveWindow.RangeSelection.Address
Set xUserRange = Application.InputBox("Lookup values :", "Kutools for Excel", xAddress, Type:=8)
If Err <> 0 Then Exit Sub
Set xUserRange = Application.Intersect(xUserRange, Application.ActiveSheet.UsedRange)
xFileName = Application.GetOpenFilename("Excel Files (*.xlsx), *.xlsx", 1, "Select a Workbook")
If xFileName = False Then Exit Sub
Application.ScreenUpdating = False
Set xSourceWb = Workbooks.Open(xFileName)
Set xSourceSh = xSourceWb.Worksheets.Item(1)
xString = "='" & xSourceWb.Path & Application.PathSeparator & _
"[" & xSourceWb.Name & "]" & xSourceSh.Name & "'!$"
For Each xRg In xUserRange
Set xFCell = xSourceSh.Cells.Find(xRg.Value, , xlValues, xlWhole, , , False)
If Not (xFCell Is Nothing) Then
xRg.Offset(0, 2).Formula = xString & GetColumn(xFCell.Column + 1) & "$" & xFCell.Row
End If
Next
xSourceWb.Close False
Application.ScreenUpdating = True
End Sub

注意：此 VBA 將在選定列後面兩列的列中返回值。例如，我在應用此 VBA 時選擇了 B 列，則值將返回在 D 列中。如果您需要更改目標列，請找到代碼 xRg.Offset(0, 2).Formula = xString & GetColumn(xFCell.Column + 1) & "$" & xFCell.Row ，並將 2 替換為其他數字，視您的需求而定。

3. 按 F5 鍵或點擊 執行 按鈕以運行此 VBA。

4. 在打開的對話框中，請指定您要查找的資料區域，然後點擊 確定 按鈕。

5. 現在，請在打開的 選擇工作簿 對話框中選擇您要查找值的工作簿，然後點擊 打開 按鈕。

現在，所有選定的值都在指定的關閉工作簿中被查找，並且相應的值在指定的列中返回。請參見截圖：