如何使Excel窗口始終位於最前面？

您是否曾經希望將Excel窗口始終放在頂部，而不會被其他窗口覆蓋？ 不幸的是，Excel沒有提供解決此任務的功能。 但是，在這裡，我可以給您一個VBA代碼來處理此工作。

使用VBA代碼使Excel窗口始終位於最前面

使用VBA代碼使Excel窗口始終位於最前面

下面的VBA代碼可以幫助您始終將Excel窗口保持在頂部，該代碼適用於Office 32位和Office 64位。

1。 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications窗口.

2。 點擊 插入 > 模塊，然後將以下代碼粘貼到 模塊窗口.

VBA代碼：始終將Excel窗口置於頂部

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

3。 然後按 F5 運行此代碼的關鍵，以及 宏 出現對話框，選擇 設置XLOnTop 選項，然後單擊 運行 按鈕。

4. 然後，您的Excel窗口將始終位於其他應用程序的頂部。

備註：如果要使Excel窗口恢復正常，只需按 F5 鍵打開 宏 對話框中，選擇 設置X正常 並點擊 運行.