如何在 Excel 中打印帶有驗證圈的工作表？

在某些情況下，我們可能會圈出一些無效的數據以使其突出顯示，但當你需要打印帶有驗證圈的工作表時，這些圈將不會被打印出來。你是否在 Excel 中遇到過這個問題？今天，我將向你展示一些快速解決此問題的技巧。

通過將驗證圈作為圖片粘貼來打印工作表

使用 VBA 代碼打印帶有驗證圈的工作表

通過將驗證圈作為圖片粘貼來打印工作表

在 Excel 中，我們無法直接打印驗證圈，但可以複製並粘貼帶有驗證圈的資料區域作為圖片，然後再進行打印。

1. 選擇要打印圈的資料區域。

2. 按下鍵盤上的 Ctrl + C 鍵進行複製，然後進入一個新的工作表，點擊某個單元格，右鍵選擇「選擇性粘貼」>「圖片」，請參閱截圖：

3. 然後你的選定區域已經作為圖片粘貼，現在當你打印新工作表時，圈將成功打印出來。

使用 VBA 代碼打印帶有驗證圈的工作表

如果你不喜歡將資料區域作為圖片粘貼，以下 VBA 代碼也可以幫助你。

1. 設置完資料有效性後，請在 Excel 中按住 Alt + F11 鍵打開 Microsoft Visual Basic for Applications 視窗。

2. 然後點擊「插入」 > 「模組」，並將以下宏粘貼到模組視窗中。

VBA 代碼：為無效數據插入紅圈

Sub AddValidationCirclesForPrinting()
'Update 20140724
Dim Rng As Range
Dim WorkRng As Range
Dim xCount As Integer
Dim xShape As Shape
On Error Resume Next
Set WorkRng = Application.ActiveSheet.Cells.SpecialCells(xlCellTypeAllValidation)
If WorkRng Is Nothing Then
    Exit Sub
End If
xCount = 0
For Each Rng In WorkRng
   If Not Rng.Validation.Value Then
       Set xShape = Application.ActiveSheet.Shapes.AddShape(msoShapeOval, Rng.Left - 2, Rng.Top - 2, Rng.Width + 4, Rng.Height + 4)
       xShape.Fill.Visible = msoFalse
       xShape.Line.ForeColor.SchemeColor = 10
       xShape.Line.Weight = 1.25
       xCount = xCount + 1
       xShape.Name = "InvalidData_" & xCount
   End If
Next
Exit Sub
End Sub

3. 然後按下 F5 鍵執行此代碼，無效數據將被紅色橢圓圈出，請參閱截圖：

4. 當你打印包含紅圈的工作表時，這些圈也會被打印出來。

注意：

使用此 VBA 代碼後，這些圈不會隨著 Excel 的「清除驗證圈」功能移除。如果你想刪除這些圈，請應用以下代碼。

VBA 代碼：刪除工作表中的驗證圈

Sub RemoveValidationCircles()
'Update 20140724
Dim xShape As Shape
For Each xShape In Application.ActiveSheet.Shapes
    If xShape.Name Like "InvalidData_*" Then
        xShape.Delete
    End If
Next
End Sub

相關文章：

如何在 Excel 中圈出無效數據？