如何在Excel中快速將數字轉換為英文單詞？

在 Excel 中將數字轉換為文字對於準備財務報告、法律文件或需要拼字金額的支票非常有用。雖然 Excel 不提供將數字直接轉換為單字的內建函數，但您可以使用多種方法來實現此目的，從使用 Visual Basic for Applications (VBA) 巨集到第三方加載項和線上工具。下面，我們將探討其中一些方法，以幫助您找到滿足您需求的最佳解決方案。

• 使用用戶定義的功能將數字轉換為貨幣詞
• 使用有用的功能將數字轉換為貨幣單詞
• 使用用戶定義的功能將數字轉換為英文單詞

使用用戶定義的功能將數字轉換為貨幣詞

如果要將數字轉換為英語貨幣單詞，則應應用下面的VBA代碼。

1. 按住 ALT + F11 鍵，然後打開 Microsoft Visual Basic應用程序窗口.

2。 點擊 插入 > 模塊，然後將以下代碼粘貼到 模塊窗口.

Function SpellNumberToEnglish(ByVal pNumber)
'Update by Extendoffice
Dim Dollars, Cents
arr = Array("", "", " Thousand ", " Million ", " Billion ", " Trillion ")
pNumber = Trim(Str(pNumber))
xDecimal = InStr(pNumber, ".")
If xDecimal > 0 Then
    Cents = GetTens(Left(Mid(pNumber, xDecimal + 1) & "00", 2))
    pNumber = Trim(Left(pNumber, xDecimal - 1))
End If
xIndex = 1
Do While pNumber <> ""
    xHundred = ""
    xValue = Right(pNumber, 3)
    If Val(xValue) <> 0 Then
        xValue = Right("000" & xValue, 3)
        If Mid(xValue, 1, 1) <> "0" Then
            xHundred = GetDigit(Mid(xValue, 1, 1)) & " Hundred "
        End If
        If Mid(xValue, 2, 1) <> "0" Then
            xHundred = xHundred & GetTens(Mid(xValue, 2))
        Else
            xHundred = xHundred & GetDigit(Mid(xValue, 3))
        End If
    End If
    If xHundred <> "" Then
        Dollars = xHundred & arr(xIndex) & Dollars
    End If
    If Len(pNumber) > 3 Then
        pNumber = Left(pNumber, Len(pNumber) - 3)
    Else
        pNumber = ""
    End If
    xIndex = xIndex + 1
Loop
Select Case Dollars
    Case ""
        Dollars = "No Dollars"
    Case "One"
        Dollars = "One Dollar"
    Case Else
        Dollars = Dollars & " Dollars"
End Select
Select Case Cents
    Case ""
        Cents = " and No Cents"
    Case "One"
        Cents = " and One Cent"
    Case Else
        Cents = " and " & Cents & " Cents"
End Select
SpellNumberToEnglish = Dollars & Cents
End Function
Function GetTens(pTens)
Dim Result As String
Result = ""
If Val(Left(pTens, 1)) = 1 Then
    Select Case Val(pTens)
        Case 10: Result = "Ten"
        Case 11: Result = "Eleven"
        Case 12: Result = "Twelve"
        Case 13: Result = "Thirteen"
        Case 14: Result = "Fourteen"
        Case 15: Result = "Fifteen"
        Case 16: Result = "Sixteen"
        Case 17: Result = "Seventeen"
        Case 18: Result = "Eighteen"
        Case 19: Result = "Nineteen"
        Case Else
    End Select
Else
Select Case Val(Left(pTens, 1))
    Case 2: Result = "Twenty "
    Case 3: Result = "Thirty "
    Case 4: Result = "Forty "
    Case 5: Result = "Fifty "
    Case 6: Result = "Sixty "
    Case 7: Result = "Seventy "
    Case 8: Result = "Eighty "
    Case 9: Result = "Ninety "
    Case Else
End Select
Result = Result & GetDigit(Right(pTens, 1))
End If
GetTens = Result
End Function
Function GetDigit(pDigit)
Select Case Val(pDigit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
    Case Else: GetDigit = ""
End Select
End Function

3。 保存此代碼，然後返回工作表，在空白單元格中，輸入此公式 = SpellNumberToEnglish（A2）( A2 是您要將數字轉換為英語貨幣單詞的單元格），然後將填充手柄向下拖動至您要應用此公式的單元格，所有數字均已拼寫為英語貨幣單詞，請參見屏幕截圖：

使用有用的功能將數字轉換為貨幣單詞

使用 Kutools for Excel 輕鬆將數字拼成單字！無論您需要英文貨幣表達還是德文數字， 庫工具 數字到單詞 此功能支援 40 多種語言，簡化您的工作流程。只需點擊幾下即可將數值轉換為精確的書面文字，從而簡化您的財務報告、法律文件等。了解 Kutools for Excel 如何讓您的資料處理更快、更準確。今天就嘗試一下，體驗效率的力量！

安裝後 Excel的Kutools，請這樣做：

1。 選擇要轉換的數字列表，然後單擊 庫工具 > 內容 > 數字到單詞，請參見屏幕截圖：

2。 在 數字到貨幣單詞 對話框，選擇你要使用的語言，這裡我選擇 English 選項從 語言 列錶框，請參見屏幕截圖：

3。 然後點擊 OK 按鈕，您將看到所有數字都已用英語貨幣單詞拼出：

更多竅門：如果您只想獲取英文單詞，而不是貨幣單詞，請查看 不轉換為貨幣 複選框 選項 部分，請參見屏幕截圖：

使用用戶定義的功能將數字轉換為英文單詞

沒有功能或公式可以幫助您直接在Excel中解決此任務，但是您可以創建一個用戶定義函數來完成該任務。 請執行以下步驟：

1. 按住 ALT + F11 鍵，然後打開 Microsoft Visual Basic應用程序窗口.

2。 點擊 插入 > 模塊，然後將以下代碼粘貼到 模塊窗口.

Function NumberstoWords(ByVal MyNumber)
'Update by Extendoffice
Dim xStr As String
Dim xFNum As Integer
Dim xStrPoint
Dim xStrNumber
Dim xPoint As String
Dim xNumber As String
Dim xP() As Variant
Dim xDP
Dim xCnt As Integer
Dim xResult, xT As String
Dim xLen As Integer
On Error Resume Next
xP = Array("", "Thousand ", "Million ", "Billion ", "Trillion ", " ", " ", " ", " ")
xNumber = Trim(Str(MyNumber))
xDP = InStr(xNumber, ".")
xPoint = ""
xStrNumber = ""
If xDP > 0 Then
xPoint = " point "
xStr = Mid(xNumber, xDP + 1)
xStrPoint = Left(xStr, Len(xNumber) - xDP)
For xFNum = 1 To Len(xStrPoint)
xStr = Mid(xStrPoint, xFNum, 1)
xPoint = xPoint & GetDigits(xStr) & " "
Next xFNum
xNumber = Trim(Left(xNumber, xDP - 1))
End If
xCnt = 0
xResult = ""
xT = ""
xLen = 0
xLen = Int(Len(Str(xNumber)) / 3)
If (Len(Str(xNumber)) Mod 3) = 0 Then xLen = xLen - 1
Do While xNumber <> ""
If xLen = xCnt Then
xT = GetHundredsDigits(Right(xNumber, 3), False)
Else
If xCnt = 0 Then
xT = GetHundredsDigits(Right(xNumber, 3), True)
Else
xT = GetHundredsDigits(Right(xNumber, 3), False)
End If
End If
If xT <> "" Then
xResult = xT & xP(xCnt) & xResult
End If
If Len(xNumber) > 3 Then
xNumber = Left(xNumber, Len(xNumber) - 3)
Else
xNumber = ""
End If
xCnt = xCnt + 1
Loop
xResult = xResult & xPoint
NumberstoWords = xResult
End Function
Function GetHundredsDigits(xHDgt, xB As Boolean)
Dim xRStr As String
Dim xStrNum As String
Dim xStr As String
Dim xI As Integer
Dim xBB As Boolean
xStrNum = xHDgt
xRStr = ""
On Error Resume Next
xBB = True
If Val(xStrNum) = 0 Then Exit Function
xStrNum = Right("000" & xStrNum, 3)
xStr = Mid(xStrNum, 1, 1)
If xStr <> "0" Then
xRStr = GetDigits(Mid(xStrNum, 1, 1)) & "Hundred "
Else
If xB Then
xRStr = "and "
xBB = False
Else
xRStr = " "
xBB = False
End If
End If
If Mid(xStrNum, 2, 2) <> "00" Then
xRStr = xRStr & GetTenDigits(Mid(xStrNum, 2, 2), xBB)
End If
GetHundredsDigits = xRStr
End Function
Function GetTenDigits(xTDgt, xB As Boolean)
Dim xStr As String
Dim xI As Integer
Dim xArr_1() As Variant
Dim xArr_2() As Variant
Dim xT As Boolean
xArr_1 = Array("Ten ", "Eleven ", "Twelve ", "Thirteen ", "Fourteen ", "Fifteen ", "Sixteen ", "Seventeen ", "Eighteen ", "Nineteen ")
xArr_2 = Array("", "", "Twenty ", "Thirty ", "Forty ", "Fifty ", "Sixty ", "Seventy ", "Eighty ", "Ninety ")
xStr = ""
xT = True
On Error Resume Next
If Val(Left(xTDgt, 1)) = 1 Then
xI = Val(Right(xTDgt, 1))
If xB Then xStr = "and "
xStr = xStr & xArr_1(xI)
Else
xI = Val(Left(xTDgt, 1))
If Val(Left(xTDgt, 1)) > 1 Then
If xB Then xStr = "and "
xStr = xStr & xArr_2(Val(Left(xTDgt, 1)))
xT = False
End If
If xStr = "" Then
If xB Then
xStr = "and "
End If
End If
If Right(xTDgt, 1) <> "0" Then
xStr = xStr & GetDigits(Right(xTDgt, 1))
End If
End If
GetTenDigits = xStr
End Function
Function GetDigits(xDgt)
Dim xStr As String
Dim xArr_1() As Variant
xArr_1 = Array("Zero ", "One ", "Two ", "Three ", "Four ", "Five ", "Six ", "Seven ", "Eight ", "Nine ")
xStr = ""
On Error Resume Next
xStr = xArr_1(Val(xDgt))
GetDigits = xStr
End Function

3。 保存並關閉此代碼，然後返回工作表，在空白單元格中輸入此公式 = NumberstoWords（A2）( A2 是您要將數字轉換為英文單詞的單元格），請參見屏幕截圖：

4。 然後按 Enter 鍵，然後選擇單元格C2，然後將填充手柄拖動到要包含此公式的範圍。 所有數值均已轉換為其相應的英語單詞。

選擇正確的方法取決於您的偏好以及您需要在 Excel 中將數字轉換為單字的頻率。 VBA 在 Excel 中提供了最大的靈活性和整合性，而加載項可以提供更簡單的解決方案。如果您有興趣探索更多 Excel 提示和技巧，我們的網站提供了數千個教學。 請點擊此處造訪它們。