如何在Outlook中回复或轉發電子郵件時保持類別？

通常，當您回复或轉發我已分類的電子郵件時，該類別將在發送的電子郵件中自動刪除。如果您希望在回复或轉發的外發電子郵件中保留該類別，本文將介紹一種處理方法。

使用VBA代碼在回复或轉發電子郵件時保留類別

1. 按住 ALT + F11 鍵打開 Microsoft Visual Basic for Applications 窗口。

2。在 Microsoft Visual Basic for Applications 窗口，雙擊 本次展望會議 來自 Project1（VbaProject.OTM） 窗格以打開模式，然後將以下代碼複製並粘貼到空白模塊中。

VBA代碼：在回复或轉發電子郵件時保留類別：

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

doc保留類別回复1